无忧启动论坛

标题: 一键制作中文版win7PE安装脚本，制作教程 [打印本页]

作者: k9o9f9 时间: 2012-7-27 20:51
标题: 一键制作中文版win7PE安装脚本，制作教程
大家好，改贴是原来 http://bbs.wuyou.net/forum.php?mod=viewthread&tid=207287&extra=page%3D1&page=1 （带远程控制、安装脚本、一键制作PE的Win7PE）补充贴，本人比较少时间上论坛，有很多问题不能即时解答，喜欢制作PE的朋友可以下载来研究一下！
本脚本运行需要安装Microsoft Windows AIK和Wn7 32位SP1的中文版的ISO文件，Microsoft Windows AIK 下载地址：

http://www.microsoft.com/zh-cn/download/details.aspx?id=5753    Windows® 自动安装工具包 (AIK)

http://www.microsoft.com/zh-cn/download/details.aspx?id=5188    Windows® 自动安装工具包 (AIK) 补充程序

  建议也一起下载 Microsoft Windows AIK  补充程序，该包支持多国语言和增加了一些程序包比如“WinPE-DOT3SVC:IEEE 802.X 身份验证协议支持”。(如WiFi），补充程序安装方法，安装完AIK之后输入
xcopy E:\ "C:\Program Files\Windows AIK\Tools\PETools" /ERDY
其中 E:\ 是 ISO 映像的根目录。

脚本的安装目录如图表示，REG目录里PE的注册表文件分别是 DEFAULT、SOFTWARE、SYSTEM，File目录 DART7.7z是微软PE诊断工具、ISO.7z是PE启动文件和驱动目录、SETUP.7z是帮助将PE安装到U盘、光盘、硬盘的脚本、SOFT.7z是第三方软件和PE系统文件支持，所有的TXT文本文档都是PE需要添加的文件列表。

  一键制作中文版win7PE安装脚本代码:

@Echo off
Title Windows PE3.1中文版32位制作脚本
ECHO.
ECHO  =============================================================================
ECHO  欢迎使用Windows PE3.1中文版32位制作工具 - 时间 = %DATE% %TIME:~0,8%
ECHO.
echo  在Windows 7操作系统中请鼠标右键“以管理员身份运行”制作中文版PE x86.cmd
echo  最好关掉“用户帐户控制”以防止Windows 7操作系统出现权限等错误
echo  脚本运行需要“Microsoft Windows AIK”程序和32位Win7光盘的install.wim文件
ECHO  =============================================================================
ECHO.
PAUSE

PUSHD %~dp0
SET TP=%CD%
SET /P WIN7WIM=请选择Win7的install.wim文件全路径名(例 F:\sources\install.wim 支持拖拽):
IF EXIST "%ProgramFiles%\Windows AIK\Tools\PETools" (
Set AikSource=%ProgramFiles%\Windows AIK\Tools\PETools
) ELSE Set /p AikSource=请选择AIK安装目录的PETools文件夹(例 C:\Program Files\Windows AIK\Tools\PETools 支持复制粘贴路径,拖拽路目录需去掉路径前后的双引号):
SET PEDest=%cd%\WINPEX86
IF EXIST "%PEDest%" REN "%PEDest%" "WINPEX86_%RANDOM%"&&ECHO WINPEX86目录已经存在，系统自动重命名"WINPEX86_随机数字"
SET ARCH=x86
Set Lang=zh-CN
Set ISOName=ZJS_Win7PEx86.iso
CALL "%AikSource%\pesetenv.cmd"

dism /cleanup-wim
CALL copype.cmd %ARCH% %PEDest%
RD /S /Q %PEDest%\mount
MD %PEDest%\1
echo 将winpe.wim挂载到一个本地目录
echo =============================================================================
Dism /Mount-Wim /WimFile:%PEDest%\winpe.wim /index:1 /MountDir:%PEDest%\1
Dism /Get-MountedWimInfo

:: 在映像中安装指定的 .cab 程序包或 .msu 程序包,本批处理已经从win7的install.wim拷贝WinPE-Scripting、WinPE-PPPoe、WinPE-DOT3SVC这3个CAB所需要的文件，不需要再重复安装这3个包
:: 如有需要安装别的CAB包，把代码贴到下面，下面的是安装例子
:: Dism /image:%PEDest%\1 /Add-Package /PackagePath:"%AikSource%\%ARCH%\WinPE_FPs\WinPE-Scripting.cab"
:: Dism /image:%PEDest%\1 /Add-Package /PackagePath:"%AikSource%\%ARCH%\WinPE_FPs\%Lang%\WinPE-Scripting_zh-CN.cab"

echo 正在拷贝文件,请等待...
echo =============================================================================
7z x "%WIN7WIM%" -y -aos -o"%PEDest%" @"%TP%\File\File.txt"
7z x "%WIN7WIM%" -y -aos -o"%PEDest%" @"%TP%\File\IME.txt"
DEL /F /Q /A "%PEDest%\1\Windows\Fonts\simsun.ttc"
7z x "%TP%\File\SOFT.7z" -y -o"%PEDest%\1\"
7z x "%TP%\File\DART7.7z" -y -o"%PEDest%\1\"
7z x "%TP%\REG\REG CN_X86.7z" -y -o"%PEDest%\1\"
7z x "%TP%\File\ISO.7z" -y -o"%PEDest%\ISO\"
7z x "%TP%\File\SETUP.7z" -y -o"%PEDest%\"
REN "%PEDest%\1\Users\Default\AppData\Roaming\Microsoft\Windows\SendTo\Desktop (create shortcut).DeskLink" 桌面快捷方式.DeskLink
REN "%PEDest%\1\Windows\System32\Explorer.exe" ErdExplorer.exe

echo 设置X盘大小为256MB
echo =============================================================================
Dism /image:%PEDest%\1 /Set-ScratchSpace:256

echo　正在精简文件,请等待...
echo =============================================================================
FOR /F "usebackq delims=" %%i IN ("%TP%\File\Del.txt") DO (
RD /S /Q "%PEDest%\1\%%i")
FOR /F "usebackq delims=" %%i IN ("%TP%\File\Del_Fonts.txt") DO (
DEL /F /S /Q /A "%PEDest%\1\Windows\Fonts\%%i")
FOR /F "usebackq delims=" %%i IN ("%TP%\File\Del_NLS.txt") DO (
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\%%i")
FOR /F "delims=" %%i IN ('dir /A-D /B %PEDest%\1\Windows\System32\kbd*.dll') DO (
if /i not "%%i"=="KBDUS.DLL" if /i not "%%i"=="KBDUSA.DLL" if /i not "%%i"=="KBDUK.DLL" DEL /F /Q /A "%PEDest%\1\Windows\System32\%%i")
DEL /F /S /Q /A "%PEDest%\1\Users\Default\NTUSER.DAT*.*"
DEL /F /S /Q /A "%PEDest%\1\Windows\inf\setupapi.offline.log"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\winpe.bmp"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\startnet.cmd"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\onlinedeploy.cmd"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\config\*.regtrans-ms"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\config\*.TM.blf"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\config\*.LOG*"
DEL /F /S /Q /A "%PEDest%\1\Windows\System32\config\BCD-Template"
DEL /F /S /Q /A "%PEDest%\ISO\boot\bootfix.bin"
RD /S /Q "%PEDest%\ISO\boot\Fonts"
RD /S /Q "%PEDest%\ISO\efi\microsoft\boot\fonts"
echo 正在精简winsxs目录，文件较多需要较多时间请等待...
CALL "%TP%\File\winsxs.exe"
ECHO PE即将完成，如有需要修改PE的内容，PE挂载目录在“%PEDest%”没有继续生成为ISO...
echo =============================================================================
PAUSE

POPD
echo 提交对winpe.wim映像的更改
echo =============================================================================
Dism /Unmount-Wim /MountDir:%PEDest%\1 /Commit
echo  winpe.wim重新生成为boot.wim,优化WIM包大小
echo =============================================================================
imagex /export /compress maximum %PEDest%\winpe.wim 1 %PEDest%\ISO\sources\boot.wim "ZJSPE"
Oscdimg -b%PEDest%\etfsboot.com -h -n -m -o -lZJSPE -t3/3/2012,00:00:00 %PEDest%\ISO %PEDest%\%ISOName%
echo WINPE3.1已经制作完成，生成的ISO镜像保存在 %PEDest% 请按任意键退出...
echo =============================================================================
pause>nul 2>nul
explorer.exe /e,%PEDest%
exit

  下载地址:
http://115.com/file/c22v3gk8#

[ 本帖最后由 k9o9f9 于 2012-7-27 21:21 编辑 ]

作者: TCLSHX 时间: 2012-7-27 20:59

原帖由 k9o9f9 于 2012-7-27 20:51 发表
大家好，改贴是原来 http://bbs.wuyou.net/forum.php?m ... ;tid=207287&extra=page%3D1&page=1 （带远程控制、安装脚本、一键制作PE的Win7PE）补充贴，本人比较少时间上论坛，有很多问题不能即时解答，喜欢制作 ...

抢沙发先...........

作者: 8696648 时间: 2012-7-27 21:41
谢谢老大，辛苦了。好资料，下载收藏。

作者: 2010ysbledmh 时间: 2012-7-27 22:00
感謝樓主的熱心發文分享

作者: gybaby123 时间: 2012-7-27 22:57
感恩樓主分享，辛苦了

作者: jiaju8 时间: 2012-7-30 21:05
能在xp系统和虚拟机里做吗

作者: k9o9f9 时间: 2012-7-31 02:11
能在xp系统和虚拟机里做吗
好像无法安装AIK工具的，虚拟机装WIN7可以

作者: gybaby123 时间: 2012-8-1 21:02
感恩樓主分享，辛苦了，115網盤出現:未绑定手机禁止分享给大众功能，请联系资源发布者获取资源!可否請樓主重新分享一下

作者: k9o9f9 时间: 2012-8-7 15:28

原帖由 gybaby123 于 2012-8-1 21:02 发表
感恩樓主分享，辛苦了，115網盤出現:未绑定手机禁止分享给大众功能，请联系资源发布者获取资源!可否請樓主重新分享一下

已经手机验证了，请大家下载

作者: 2012jhp 时间: 2012-8-31 08:38
标题: 回复 #1 k9o9f9 的帖子
报告楼主，我安装你的方法，连路径都设置成和你一模一样的，右键管理员运行后，指定WIM路径运行后，出现一连串找不到指定路径的字眼。

作者: 2011Tduy09 时间: 2012-9-26 09:13
Can up to other Host, I cant down 115!!!!!!
Tks

作者: 2011Tduy09 时间: 2012-9-26 12:25
Can up to http://pan.baidu.com
thank all

作者: 阿弥陀佛 时间: 2012-9-26 12:38

原帖由 2011Tduy09 于 2012-9-26 12:25 发表
Can up to http://pan.baidu.com
thank all

Wait a minute, Uploading...

OK，now you can download from here
http://pan.baidu.com/share/link?shareid=65778&uk=538680821

[ 本帖最后由 2012txm 于 2012-9-26 13:04 编辑 ]

作者: 2011Tduy09 时间: 2012-9-26 14:20
Thank much :D! You can help up Ver Eng from http://bbs.wuyou.net/forum.php?mod=viewthread&tid=207287&extra=page%3D1&page=1

作者: 2011Tduy09 时间: 2012-9-26 16:02
Thank All!!!!! i can down Ver Eng !!!!!

作者: 2011Tduy09 时间: 2012-9-26 21:17
Can Add support Audio ? ? ?

作者: 2012kun 时间: 2012-9-26 21:56
我有罪啊。我没看懂、、、

作者: 2011Tduy09 时间: 2012-9-27 09:39
I want build 1 ver Eng add support Sound Audio. tks

作者: anythingsky 时间: 2012-9-27 10:20
标题: 不好用
不知道为什么，我用了一下你批处理，感觉不好用，不知道什么原因。看样子还是不成熟，我也装了AIK 默认安装的路径，还有一点我不明白既然已经安装AIK为什么还要原版的install.wim干什么啊。

作者: 阿弥陀佛 时间: 2012-9-27 11:18

原帖由 anythingsky 于 2012-9-27 10:20 发表
不知道为什么，我用了一下你批处理，感觉不好用，不知道什么原因。看样子还是不成熟，我也装了AIK 默认安装的路径，还有一点我不明白既然已经安装AIK为什么还要原版的install.wim干什么啊。

用来提取需要的其他组件。

作者: 双响炮 时间: 2018-9-2 16:36
不知现在有没有更新，支持UEFI的呀

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)