64位Win7装PE不能启动

2013hnnyxa · 发表于 2016-5-28 13:10:32

UEFI+GPT,顺利安装了64位Win7后，从Wepe中提取boot.wim及boot.sdi，复制到ESP分区（扩容到1.2G，FAT16格式），用BOOTICE编辑系统启动菜单，电脑启动后选择PE系统，走完白色进度条后，又返回系统启动菜单，就是进不了PE，谁能帮助解决一下？

注：这个boot.wim在Win10的本子上是可以顺利启动的！

不知 · 发表于 2016-6-24 21:52:24

把winpe的efi文件夹也复制到esp分区。

不知 · 发表于 2016-6-24 21:52:36

把winpe的efi文件夹也复制到esp分区。

红毛樱木 · 发表于 2016-6-25 01:31:01

解释下原理给你听，您就清楚为什么了。
win7的bootmgr和bootmgr.efi不能用来引导高版本的OS。反之是可行的。这样你就知道该怎么做了

x9tian · 发表于 2016-6-26 12:58:26

红毛樱木发表于 2016-6-25 01:31
解释下原理给你听，您就清楚为什么了。
win7的bootmgr和bootmgr.efi不能用来引导高版本的OS。反之是可行的 ...

樱木，这个我可以非常直截的告诉你，你错了！
曾经我也是和你一样的想法，直到去年年底研究USB3.0和nvme时，才无意间发现了这个事情。
WIN7可以引导高版本的PE只是非常复杂，要用bcdedit命令生成！ Bootice这些什么的是完全做不到的或都说它生成的{id}经不起高版本的考验

红毛樱木 · 发表于 2016-6-26 15:50:41

x9tian 发表于 2016-6-26 12:58
樱木，这个我可以非常直截的告诉你，你错了！
曾经我也是和你一样的想法，直到去年年底研究USB3.0和nvme ...

我之前用bcdedit在win7下引导win8的wim不成功。。。后来换bootmgr才行。
也可能是我写的bcdedit命令问题。。。

x9tian · 发表于 2016-6-26 18:02:26

红毛樱木发表于 2016-6-26 15:50
我之前用bcdedit在win7下引导win8的wim不成功。。。后来换bootmgr才行。
也可能是我写的bcdedit命令问题 ...

那是你方法不对，用我写的这个批处理
1：当PE.wim 和BOOT.SDI在同一文件夹时，直截拖动文件夹到本批处理窗口；
2：当PE.wim在根目录时直截拖放任意分区任意文件夹到本批处理，它会让你设定单独的WIM文件
3：默认指定了系统分区BOOT文件夹下的boot.SDI,没有会要求指定
4： BOOT.SDI和Wim可以是任意名,可以指定BCD文件，不指定为当前系统的（PE下必须指定BCD且必须有bcdedit组件）

@echo off
echo.请拖放要处理PE目录
set var=
set /p var=
if not defined var (cls&%0)
if /i "%var:~-4,1"=="." (cls&%0)
cd /d %var% && for /f %%i in ('dir /a-d/b/s *.wim *.sdi') do (
if /i "%%~xi"==".wim" set "wim=%%i"
if /i "%%~xi"==".sdi" set "sdi=%%i"
)
:wim
if defined wim (
set "drw=%wim:~0,2%"
set "dpw=%wim:~2%"
) else (
echo.%var% 目录不存在WIM文件
echo.请指定PE 的 WIM文件
set /p wim=
goto :wim
)
:sdi
if defined sdi (
set "dri=%sdi:~0,2%"
set "dpi=%sdi:~2%"
) else (
if exist %SystemDrive%\boot\boot.sdi (
set "dri=%SystemDrive%"
set "dpi=\boot\boot.sdi"
) else (
echo. %var% 目录不存在SDI文件
echo. 请指定SDI文件
set /p sdi=
goto :sdi
)
)
:st
set store=
echo.将要外理的BCD拖入本窗口,如果是添加到当前操作系统直截回车
echo.
set /p store=
if defined store set "store=/store %store%"
:name
cls
echo. 请为启动菜单取个名：
echo.
set name=
set /p name=
if not defined name goto :name
for /f "tokens=2 delims={}" %%i in ('bcdedit %store% /create /d "%name%" /device ') do set "guid={%%i}"
rem 设置boot.sdi所在分区
bcdedit %store% /set %guid% ramdisksdidevice partition=%dri%
rem 设置BOOT.sdi所在路径
bcdedit %store% /set %guid% ramdisksdipath %dpi%
for /f "tokens=2 delims={}" %%i in ('bcdedit %store% /create /d "%name%" /application osloader ') do set "guid2={%%i}"
rem ——设定启动设备（即：boot.wim文件）
bcdedit %store% /set %guid2% device ramdisk=[%drw%]%dpw%,%guid%
rem ——设定系统设备（即：boot.wim文件）
bcdedit %store% /set %guid2% osdevice ramdisk=[%drw%]%dpw%,%guid%
rem ——设定启动程序（winload.exe）的路径
bcdedit %store% /set %guid2% path \windows\system32\winload.exe
rem ——设定系统的根目录
bcdedit %store% /set %guid2% systemroot \windows
rem ——开启detecthal支持
bcdedit %store% /set %guid2% detecthal yes
rem ——开启winpe支持
bcdedit %store% /set %guid2% winpe yes
rem ——设置nx为optin
bcdedit %store% /set %guid2% nx optin
rem ——设置为最后一项显示。
bcdedit %store% /displayorder %guid2% /addlast
pause

复制代码

x9tian · 发表于 2016-6-26 18:33:52

上面的批处理，winload.exe那项改成你PE启动的*.Efi路径

		自动登录	找回密码
密码			注册

[求助] 64位Win7装PE不能启动

点评