我做的启动盘里的ghost能启动，但无法浏览到光盘里的文件

haibara114

我用easyboot做了一个启动盘，集成了一些小工具，有一项菜单是启动ghost11，其中我用的.img文件是从网上下载的MSDOS7.1启动盘改制的，我把ghost11.exe，mouse.com，mouse.ini，ezboot.com文件放在ghost文件夹添加到.img文件里，并且改了autoexec.bat的内容，以及新添加了一个批处理goghost.bat。以下是这两个批处理的内容：

autoexec.bat的内容：
@ECHO OFF
PROMPT $P$G
PATH=A:\;..
LFNFOR ON
SET DIRCMD=/4
MODE CON RATE=32 DELAY=1
LH KILLER
LH SHSUCDX /D:IDE-CD /Q /~+
LH DOSKEY
LH DOSLFN
ECHO.
ECHO Now you are in MS-DOS 7.10 prompt.
ECHO.
call goghost.bat

goghost.bat的内容：
@echo off
cd ghost
MOUSE.COM
ghost.EXE
ezboot.com

除了autoexec.bat里面最后一句（红色的那一句）是我加的，以及goghost.bat和ghost文件夹是我新加到.img文件里的，其他东西我都没动。

然后我把自己的系统备份文件GhostXp.gho放到GhostXp文件夹，再把GhostXp文件夹放到光盘根目录。刻盘。

刻盘启动后，能进入菜单界面，并且选择ghost菜单能进入ghost，但是在ghost里，from image选项能浏览到光盘里面，但看不到GhostXp文件夹，也看不到ezboot文件夹，什么都没有。


因为我是usb外置光驱，我怀疑是光驱问题，后来我把盘拿到同学那试了下能看到文件夹，于是我到网上下了USBCD.SYS加到镜像文件里，然后改了config.sys，还是看不到（红色那句是我加的）。

config.sys的内容：
DOS=HIGH,UMB
DEVICE=HIMEM.SYS
REM DEVICE=EMM386.EXE NOEMS
DEVICEHIGH=VIDE-CDD.SYS /D:IDE-CD
DEVICEHIGH=USBCD.SYS
COUNTRY=001,437,COUNTRY.SYS
SHELL=COMMAND.COM /P /E:640
FILES=30
FCBSHIGH=4,0
BUFFERSHIGH=20
LASTDRIVEHIGH=26
STACKSHIGH=9,256
SET TEMP=.
SET TMP=.
REM MS-DOS 7.10 Boot Disk


我想请教一下是怎么回事？该怎么解决？谢谢！

lianjiang

给你一个例子供参考。
config：
－－－－－－－－－－－
[MENU]
MENUITEM=M1,Boot with EMM386(NOEMS) [Protected Mode]
MENUITEM=M2,Boot with UMBPCI [Real Mode]
MENUITEM=M3,Boot with EMM386(NOEMS), NTFS and SCSI/USB drives support(if any)
MENUITEM=M4,Boot with UMBPCI, NTFS and SCSI/USB drives support(if any)
MENUITEM=M5,View the README file only(with Chinese support)
MENUITEM=M6,Shutdown or restart the computer
MENUDEFAULT=M1,15

[M1]
DEVICE=ECHO.SYS L/o/a/d/i/n/g CONFIG.SYS /w/i/t/h EMM386...
DEVICE=HIMEM.SYS
DEVICE=EMM386.EXE NOEMS
INCLUDE CD

[M2]
DEVICE=ECHO.SYS L/o/a/d/i/n/g CONFIG.SYS /w/i/t/h UMBPCI...
DEVICE=ECHO.SYS
DEVICE=HIMEM.SYS
DEVICE=UMBPCI.SYS
DEVICE=LOWDMA.SYS
INCLUDE CD

[M3]
DEVICE=ECHO.SYS L/o/a/d/i/n/g CONFIG.SYS /w/i/t/h EMM386...
DEVICE=HIMEM.SYS
DEVICE=DUSE.EXE INT EMU CDW=3 DDW=3 XFER=32 DRIVES=2 CDD=USB-CD
DEVICE=EMM386.EXE NOEMS
INCLUDE CD
INCLUDE USB

[M4]
INCLUDE M2
DEVICE=DUSE.EXE INT EMU CDW=3 DDW=3 XFER=32 DRIVES=2 CDD=USB-CD
INCLUDE USB

[M5]
DEVICE=ECHO.SYS Y/o/u /h/a/v/e /c/h/o/s/e/n /t/o /v/i/e/w README /o/n/l/y.
INCLUDE M6

[M6]
DEVICE=ECHO.SYS P/l/e/a/s/e /w/a/i/t...
DEVICE=HIMEM.SYS

[USB]
DEVICE=ECHO.SYS L/o/a/d/i/n/g SCSI//USB /d/r/i/v/e/s /s/u/p/p/o/r/t...
DEVICE=USBASPI.SYS /R /V /NORST
DEVICE=ASPIOHCI.SYS /INT /ALL
DEVICE=ASPIUHCI.SYS /INT /ALL
DEVICEHIGH=DI1000DD.SYS
DEVICEHIGH=USBCD.SYS /D:USB-CD
DEVICE=ECHO.SYS

[CD]
DEVICEHIGH=UDMA.SYS
DEVICEHIGH=VIDE-CDD.SYS /D:IDE-CD

[COMMON]
DEVICE=ECHO.SYS M/a/d/e /b/y W/e/n/g/i/e/r. C/h/i/n/a DOS U/n/i/o/n.
DEVICE=ECHO.SYS A/l/l /r/i/g/h/t/s /r/e/s/e/r/v/e/d. 2002-2004.
SHELL=COMMAND.COM /P /E:640
SET TMP=C:\
SET TEMP=C:\
DOS=HIGH,UMB,AUTO
NUMLOCK=OFF
FCBSHIGH=4,0
FILESHIGH=30
BUFFERSHIGH=20,0
LASTDRIVEHIGH=32
STACKSHIGH=9,256
COMMENT Made by Wengier. China DOS Union.
COMMENT All rights reserved. 2002-2004.
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

autoexec
－－－－－－－－－－－－－
@ECHO OFF
KPUSH 27 27
KPUSH>NUL
REM Made by Wengier. China DOS Union.
REM All rights reserved. 2002-2003.
TM /F
LH KILLER
LH DOSKEY
LH CTMOUSE
::Note: The following line is for the compatibility on some systems:
LH CTMOUSE>NUL
IF %CONFIG%#==M6# GOTO SHUT
IF NOT %CONFIG%#==M5# GOTO BOOT
ECHO.
ECHO Now preparing to open README with Chinese support...
XMSDSK 80 /Y>NUL
FINDRAMD>NUL
IF %RAMDRIVE%#==# ECHO Can't create RAM disk!
IF %RAMDRIVE%#==# GOTO SHUT
EXTRACT /E /L %RAMDRIVE%\ DOSET.CAB EDIT.COM>NUL
XZL
%RAMDRIVE%\EDIT README.TXT
CLS
XZL /Q
:SHUT
CLS
WBAT BOX "Please enter your choice:",Shutdown the computer,Restart the computer
IF NOT ERRORLEVEL 3 GOTO ANS
WBAT BOX (RED ON YELLOW) "Note: Please make a choice!",OK
GOTO SHUT
:ANS
IF ERRORLEVEL 2 GOTO RES
ECHO Now trying to shutdown the computer..
ECHO.
SHUTDOWN S
ECHO.
ECHO Shutdown failed. Your computer may not have an ATX power.
:RES
ECHO Now restart the computer..
ECHO.
SHUTDOWN R
GOTO END
:BOOT
SET SM=
DREADY C:
IF ERRORLEVEL 1 ECHO Warning: Can't find any valid hard drives!
IF ERRORLEVEL 1 GOTO NOHD
ECHO Y|LOCK C:>NUL
ECHO.
ECHO Now trying to load the hard disk cache to speed the drives up...
WBAT BOX "Please choose the hard disk cache you like in 8 seconds:",PC-CACHE,SMARTDRV,Cancel #1,8
IF ERRORLEVEL 3 ECHO Cancelled.
IF NOT ERRORLEVEL 2 PCCACHE /SIZEXT:4096 /WRITE:OFF /WIN /MINI
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 SET SM=Y
:NOHD
LH SHSUCDX /D:?IDE-CD /D:?USB-CD
XMSDSK 4096 /Y
ECHO Now setting up the RAM disk...
FINDRAMD>NUL
IF %RAMDRIVE%#==# GOTO NORAM
IF NOT EXIST %RAMDRIVE%\TEMP\NUL MD %RAMDRIVE%\TEMP
SET TMP=%RAMDRIVE%\TEMP
SET TEMP=%RAMDRIVE%\TEMP
IF NOT EXIST %RAMDRIVE%\SYSTEM\NUL MD %RAMDRIVE%\SYSTEM
COPY COMMAND.COM %RAMDRIVE%\SYSTEM>NUL
IF NOT EXIST %RAMDRIVE%\SYSTEM\COMMAND.COM ECHO Warning: Failed to copy files!
IF NOT EXIST %RAMDRIVE%\SYSTEM\COMMAND.COM GOTO COPYERR
SET COMSPEC=%RAMDRIVE%\SYSTEM\COMMAND.COM
EXTRACT /E /Y /L %RAMDRIVE%\SYSTEM DOSET.CAB>NUL
EXTRACT /E /Y /L %RAMDRIVE%\SYSTEM VC.CAB>NUL
ECHO The necessary tools have been successfully loaded to drive %RAMDRIVE%.
:COPYERR
PATH=%RAMDRIVE%.;%RAMDRIVE%\SYSTEM
IF %SM%#==Y# LH SMARTDRV 4096 2048 /X
GOTO NEXT
:NORAM
ECHO Warning: Can't create RAM disk!
IF %SM%#==Y# ECHO          Can't load SMARTDRV!
SET COMSPEC=A:\COMMAND.COM
:NEXT
SET SM=
SET DIRCMD=/OGN /4
SET PROMPT=$P$G
PATH=%PATH%;C:.;A:.;..
LH ZENO /Q
LH MOUSCLIP /M
WBAT BOX "Please choose the code page for LFNs you want to use:",CP437(English),CP936(S.Chinese),Disable LFN #1,8
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 LH DOSLFN /C- /Z:CP437UNI.TBL
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 LH DOSLFN /C- /Z:CP936UNI.TBL
IF %CONFIG%#==M3# IF %RAMDRIVE%#==# ECHO Warning: Can't load NTFS drives support!
IF %CONFIG%#==M4# IF %RAMDRIVE%#==# ECHO Warning: Can't load NTFS drives support!
IF %CONFIG%#==M3# IF NOT %RAMDRIVE%#==# NTFSDOS /U
IF %CONFIG%#==M4# IF NOT %RAMDRIVE%#==# NTFSDOS /U
LH ESCAPE
FINDCD /Q
CLS
WRITEXT 1 1 -f15 Note:
ECHO.
IF NOT %CDROM%#==# ECHO For accessing CD/DVD drive, use the drive letter %CDROM%(1st).
IF NOT %RAMDRIVE%#==# ECHO For accessing RAM drive, use the drive letter %RAMDRIVE%.
IF NOT %CONFIG%#==M3# IF NOT %CONFIG%#==M4# ECHO For accessing NTFS drives(if any), type NTFSDOS on the command line.
ECHO At any time, you can press F12 key to return to DOS, or use the mouse.
BREAK ON
LFNFOR ON
IF %RAMDRIVE%#==# GOTO END
ECHO.
ECHO Press ENTER in 2 seconds if you want to start Volkov Commander..
WAIT 2
SET VC=
IF ERRORLEVEL 13 IF NOT ERRORLEVEL 14 SET VC=1
IF %VC%#==# ECHO Skipped.
ECHO.
ECHO Now you're in MS-DOS 7.10 prompt. [Made by Wengier, China DOS Union]
ECHO.
ECHO For more information, please look at README.TXT on this disk.
ECHO To start Chinese system for Chinese, type XZL on the command line.
WRITEXT 0+ 1 "Any comments, please come to the forum at: " -f15 http://dosbbs.2ya.com/ -f7
ECHO.
IF %VC%#==# GOTO END
SET VC=
ECHO.
ECHO Starting Volkov Commander...
ECHO.
SET DIF=
STRINGS UMB=UMBLARGE >NUL
STRINGS DIF=SUB %UMB%,30720 >NUL
SET UMB=
IF NOT %DIF%#==# GOTO LH
VC
GOTO END
:LH
SET DIF=
LH VC
:END
ECHO.

弄潮儿-NET

例子中竟然有:lol

haibara114

哇，看的头都大了。我是菜鸟啊，我不需要很多功能，我现在只想知道为什么能启动Ghost，但是却在from image选项里浏览到光盘后，里面什么都看不到。:'(

lianjiang

你就把USB光驱相关部分拿来试试即可。
来源“MS-DOS7.1超级通用启动盘”

haibara114

谢谢，我下了一个MS-DOS7.1超级通用启动盘，慢慢摸索摸索吧。

弄潮儿-NET

55252,48314,54014,45784,52932,48382,48336,49611,41919,46246,50384,49847,47613,53947,53186,41379,47351,52923,48332,53496,41389,