设为首页收藏本站
切换到宽版 Language

 找回密码
 注册
搜索
无忧启动论坛»论坛 › ::数码生活:: › Windows技术讨论区 › GHOST完成后根据网卡MAC自动设置机名和IP的批处理 ...
系统gho:最纯净好用系统下载站投放广告、加入VIP会员，请联系 微信:wuyouceo
返回列表 发新帖
查看: 3004|回复: 4

GHOST完成后根据网卡MAC自动设置机名和IP的批处理

[复制链接]
pk4321
发表于 2007-10-13 15:31:09 | 显示全部楼层 |阅读模式
---> 升级权限
  1. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  2. :: 领星动网 www.lxasp.com
  3. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  4. :: 主要用于电脑机房的全网GHOST后的自动更改设置
  5. :: 支持一台电脑有多张网卡（最多5块网卡）的机器
  6. :: 使用方法：
  7. :: 一、编辑好IP.BAT文件中的“机名、MAC、IP”等列表信息
  8. ::     （请事先收集好你的机房的“机名”“MAC”等信息）
  9. :: 二、在制作GHOST 镜像文件前，复制IP.BAT文件到系统盘任意目录
  10. ::     （例如 C:\ 或 C:\Windows 等）并双击此IP.BAT文件
  11. :: 三、进入DOS或光盘WINPE 运行 GHOST，创建系统盘的GHO镜像文件
  12. :: 四、进行机房的全网 GHOST，完成后会自动运行IP.BAT并自动重启
  13. :: 五、检查机房中的每台机器是否正确设置了“机名”和“IP”信息
  14. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  15. @ECHO OFF
  16. @cls
  17. ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::
  18. ECHO :: GHOST完成后根据网卡MAC自动设置机名和IP的批处理 ::
  19. ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::

  21. ::::清空环境变量
  22. Set IPAddress=
  23. Set strMac=
  24. Set MacAddress=
  25. Set CName=
  26. Set scfile=
  27. Set sc=
  28. Set MacWMIC=
  29. Set ConnName=

  31. If not "%1"=="run" Goto setboot

  33. cd/d %temp%

  35. REM ::::请手动修改列表
  36. ECHO [ComputerName] [MacAddress] [IPAddress] >iplist.txt
  37. ECHO LX001  00-04-01-02-09-90  192.168.1.1 >>iplist.txt
  38. ECHO LX002  00-04-01-02-09-91  192.168.1.2 >>iplist.txt
  39. ECHO LX003  00-04-01-02-09-92  192.168.1.3 >>iplist.txt
  40. ECHO LX004  00-04-01-02-09-93  192.168.1.4 >>iplist.txt
  41. ECHO LXASP  00-03-FF-93-39-9F  192.168.0.10 >>iplist.txt

  43. REM ::::请手动修改子网掩码
  44. Set mask=255.255.255.0
  45. REM ::::请手动修改默认网关
  46. Set gway=192.168.0.1

  48. ECHO :::: 开始查找网卡 ::::

  50. ::::获取机器的TCP/IP 配置
  51. if exist ipconfig.txt del ipconfig.txt
  52. ipconfig /all >ipconfig.txt

  54. ::::分离出机器的物理地址，并保存到 ( phyaddr.txt) 文件中
  55. if exist phyaddr.txt del phyaddr.txt
  56. if exist phyaddr1.txt del phyaddr1.txt
  57. find "Physical Address" ipconfig.txt >phyaddr.txt

  59. Set sc=1
  60. Set scfile=phyaddr.txt
  61. goto scan

  63. ::::多网卡时，扫描每个网卡MAC地址
  64. :rescan1
  65. Set sc=%sc%1
  66. Set scfile=phyaddr1.txt
  67. find /v "%strMac%" phyaddr.txt >%scfile%
  68. Goto scan

  70. :rescan2
  71. Set sc=%sc%1
  72. Set scfile=phyaddr.txt
  73. find /v "%strMac%" phyaddr1.txt >%scfile%
  74. Goto scan

  76. :scan
  77. ::::从(c:\phyaddr.txt)文件中取得物理地址字符串，并赋给变量"MacAddress"
  78. for /f "skip=2 tokens=12" %%M in (%scfile%) do set strMac=%%M

  80. ::::以变量"strMac"为关键字搜索(iplist.txt)中相同的字符串行，并保存到(PCCfg.txt)
  81. find "%strMac%" iplist.txt >PCCfg.txt

  83. ::::找出机器名(从"PCCfg.txt"中分离出 机器名字段，并赋给变量"CName")
  84. for /f "skip=2 tokens=1" %%N in (PCCfg.txt) do set CName=%%N

  86. if not "%CName%"=="" Goto found
  87. ::::支持最多扫描5个网卡
  88. If "%sc%"=="11111" Goto failed
  89. If "%sc%"=="1" Goto rescan1
  90. if %scfile%==phyaddr.txt Goto rescan1
  91. if %scfile%==phyaddr1.txt Goto rescan2
  92. :found
  93. ECHO 本机 MAC: %strMac%
  94. ECHO 目标名称: %CName%

  96. ::::显示IP地址. (从"PCCfg.txt"中分离出 IP地址字段，并赋给变量"IPAddress")
  97. for /f "skip=2 tokens=3" %%I in (PCCfg.txt) do set IPAddress=%%I
  98. ECHO 目标地址: %IPAddress%

  100. ::::显示网卡MAC地址.(从"PCCfg.txt"中分离出 MAC地址字段，并赋给变量"MacAddress")
  101. for /f "skip=2 tokens=2" %%M in (PCCfg.txt) do set MacAddress=%%M
  102. ECHO 目标 MAC: %MacAddress%

  104. ::::创建注册表文件
  105. ::::用变量"%CName%"去替换实际的机器名
  106. ECHO Windows Registry Editor Version 5.00 >PCName.reg
  107. ECHO.>>PCName.reg
  108. ECHO [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName] >>PCName.reg
  109. ECHO "ComputerName"="%CName%" >>PCName.reg
  110. ECHO.>>PCName.reg
  111. ECHO [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters] >>PCName.reg
  112. ECHO "NV Hostname"="%CName%" >>PCName.reg
  113. ECHO "Hostname"="%CName%" >>PCName.reg

  115. ECHO :::: 正在更改设置 ::::
  116. REM ::::导入注册表文件。用的时候把" :: "去掉
  117. regedit /s PCName.reg

  119. ::::找出MAC地址所对应的连接名称
  120. for /f "tokens=1,2,3,4,5,6 delims=-" %%A in ("%MacAddress%") do set MacWMIC=%%A:%%B:%%C:%%D:%%E:%%F

  122. WMIC NIC WHERE "MACAddress='%MacWMIC%' AND NetConnectionID!=NULL" GET NetConnectionID /value >phyaddr.txt

  124. WMIC NIC WHERE "MACAddress='%MacWMIC%' AND NetConnectionID!=NULL" GET NetConnectionID /value >phyaddr.txt

  126. Type phyaddr.txt >phyaddr1.txt

  128. for /f "skip=2 tokens=2* delims==" %%A in (phyaddr1.txt) do set ConnName=%%A

  130. Echo 连接名称: %ConnName%

  132. REM ::::修改IP地址。用的时候把" :: "去掉
  133. netsh interface ip set address name="%ConnName%" source=static addr=%IPAddress% mask=%mask% gateway=%gway% gwmetric=1

  135. ECHO :::: 准备重启 ::::
  136. setlocal

  138. ::::删除临时文件
  139. echo [version] > ipdel.inf
  140. echo signature=$chicago$ >> ipdel.inf
  141. echo [defaultinstall] >> ipdel.inf
  142. echo delfiles=delfiles1 >> ipdel.inf
  143. echo delfiles=delfiles2 >> ipdel.inf
  144. echo [destinationdirs] >> ipdel.inf
  145. echo delfiles1=16391 >> ipdel.inf
  146. echo delfiles2=01 >> ipdel.inf
  147. echo [delfiles1] >> ipdel.inf
  148. echo ip.lnk,,,1 >> ipdel.inf
  149. echo [delfiles2] >> ipdel.inf
  150. echo PCCfg.txt,,,1 >> ipdel.inf
  151. echo PCName.reg,,,1 >> ipdel.inf
  152. echo ipconfig.txt,,,1 >> ipdel.inf
  153. echo iplist.txt,,,1 >> ipdel.inf
  154. echo phyaddr1.txt,,,1 >> ipdel.inf
  155. echo phyaddr.txt,,,1 >> ipdel.inf
  156. RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultInstall 128 .\ipdel.inf
  157. del ipdel.inf

  159. ::::准备重启的文件
  160. echo [version] > reboot.inf
  161. echo signature=$chicago$ >> reboot.inf
  162. echo [defaultinstall] >> reboot.inf
  163. REM ::::立即重启。用的时候把" :: "去掉
  164. RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultInstall 1 .\reboot.inf
  165. del reboot.inf

  167. Goto end

  169. :setboot
  170. Echo [Version] >ipstart.inf
  171. Echo Signature="$CHICAGO$" >>ipstart.inf
  172. Echo [DefaultInstall] >>ipstart.inf
  173. Echo UpdateInis = AddLink >>ipstart.inf
  174. Echo [AddLink] >>ipstart.inf
  175. Echo setup.ini, progman.groups,, "group1=""%%16391%%""" >>ipstart.inf
  176. Echo setup.ini, group1,,"""IP"",""""""%%01%%\ip.bat"""" run"",,,,"""",""ip.bat""" >>ipstart.inf
  177. RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultInstall 128 .\ipstart.inf
  178. del ipstart.inf

  180. Echo 完成在“开始”菜单的“启动”中创建快捷方式。
  181. Echo 请在此之后使用GHOST创建此分区的GHO镜像文件。
  182. pause

  184. Goto End

  186. :failed
  187. ECHO !!!! 查找网卡失败 !!!!
  188. :end
复制代码

[ 本帖最后由 pk4321 于 2007-10-13 03:32 PM 编辑 ]
回复

使用道具 举报

发表于 2007-10-13 15:56:38 | 显示全部楼层
---> 升级权限
好象挺好，正如LZ说的

主要用于电脑机房的全网GHOST后的自动更改设置

主机名变成MAC地址的话，，貌似也不方便……
回复

使用道具 举报

benq007
发表于 2007-10-15 18:53:16 | 显示全部楼层
---> 升级权限
:lol 有没有具体的例子啊？？
回复

使用道具 举报

发表于 2007-11-19 12:55:15 | 显示全部楼层
---> 升级权限
谢谢了，就是没地方试试
回复

使用道具 举报

skuny
发表于 2007-11-20 10:42:31 | 显示全部楼层
---> 升级权限
有没有经过实战！！
这到能省不少事
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|捐助支持|无忧启动 ( 闽ICP备05002490号-1|闽公网安备35020302032614号 )

GMT+8, 2026-4-23 18:19

Powered by Discuz! X5.0

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表