在批处理脚本中嵌套使用mshta创建快捷方式出错

Anson4

因为新版本的系统的mshta组件被移除，所以大量使用mshta的脚本需要更新。

在此过程中，遇到了嵌套使用mshta的情况下，虽然成功地创建快捷方式，但是mshta提示缺少右括号（不嵌套，该指令单独一行时运行正常）。
在保持嵌套的情况下，这段代码有什么办法修复吗？

1. IF /i "%WinPE%" EQU "1" (
   
2.         PECMD.exe LINK %Desktop%\NotePad++,%CD%\Notepad++.exe,,%CD%\Notepad++.exe#0
   
3. ) ELSE (
   
4.         IF EXIST "%SystemRoot%\System32\mshta.exe" (
   
5.                 Start "" /min mshta.exe VBScript:Execute("Set WshShell=CreateObject(""WScript.Shell""):Set Shortcut=WshShell.CreateShortcut(WshShell.SpecialFolders(""Desktop"") & ""\Notepad++.lnk""):Shortcut.TargetPath=""%~dp0Notepad++.exe"":Shortcut.WorkingDirectory=""%~dp0"":Shortcut.Save:close")
   
6.                 Start "" /min mshta.exe VBScript:Execute("Set WshShell=CreateObject(""WScript.Shell""):Set Shortcut=WshShell.CreateShortcut(WshShell.SpecialFolders(""Programs"") & ""\Notepad++.lnk""):Shortcut.TargetPath=""%~dp0Notepad++.exe"":Shortcut.WorkingDirectory=""%~dp0"":Shortcut.Save:close")
   
7.         ) ELSE (
   
8.                 IF EXIST "%SystemRoot%\System32\WindowsPowerShell\v1.0\Powershell.exe" (
   
9.                         Powershell.exe -Command "$WshShell = New-Object -ComObject WScript.Shell; $LnkPath = [Environment]::GetFolderPath('Desktop'); $Shortcut = $WshShell.CreateShortcut($LnkPath + '\Notepad++.lnk'); $Shortcut.TargetPath = \"%~dp0Notepad++.exe\";$Shortcut.WorkingDirectory = \"%UserProfile%\";$Shortcut.WindowStyle=1;$Shortcut.Save();"
   
10.                         Powershell.exe -Command "$WshShell = New-Object -ComObject WScript.Shell; $LnkPath = [Environment]::GetFolderPath('Programs'); $Shortcut = $WshShell.CreateShortcut($LnkPath + '\Notepad++.lnk'); $Shortcut.TargetPath = \"%~dp0Notepad++.exe\";$Shortcut.WorkingDirectory = \"%UserProfile%\";$Shortcut.WindowStyle=1;$Shortcut.Save();"
    
11.                 )
    
12.         )
    
13. )
    

复制代码

bfgxp

不要用mshta了，因为最新的win11系统已经不支持了。在xb21cn的精简office中已经改成调用一个小工具实现创建快捷方式了。

smile_z

学习一下

窄口牛

文本编辑器选择编码格式为bat，就可以对一下括号的关系。

guong

来学习的

Anson4

窄口牛 发表于 2026-3-20 09:11
文本编辑器选择编码格式为bat，就可以对一下括号的关系。

括号肯定是成对出现的，这个检查了没有问题。

Anson4

bfgxp 发表于 2026-3-20 06:47
不要用mshta了，因为最新的win11系统已经不支持了。在xb21cn的精简office中已经改成调用一个小工具实现创建 ...

研究一下多一条路嘛
而且对于一些小软件，为了创建快捷方式带上第三方工具不太爽。
现在的目的是：有mshta就用mshta，没有就用powershell。
没有直接用powershell，是因为它的运行速度有点慢。

Anson4

bfgxp 发表于 2026-3-20 06:47
不要用mshta了，因为最新的win11系统已经不支持了。在xb21cn的精简office中已经改成调用一个小工具实现创建 ...

那个小工具是不是 Shortcut？

2010minyang

虽然不知道LZ在说什么但是感觉很厉害的样子～

redyear2026

在批处脚本中，mshta 代码落入圆括号这类复合语块里，据说会有一个 '禁则'，即不能出现嵌套双引号或嵌套单引号，一个简单解法是用 call 方法解围，如下示例

1. @echo off
   
2. if exist "%SystemRoot%\System32\mshta.exe" (
   
3.    call :toMSHTA
   
4. )
   
5. exit/b
   
6. :toMSHTA
   
7.     Start "" /min mshta.exe VBScript:Execute("Set
   
8. WshShell=CreateObject(""WScript.Shell""):Set
   
9. Shortcut=WshShell.CreateShortcut(WshShell.SpecialFolders(""Desktop"")
   
10. &
    
11. ""\Notepad++.lnk""):Shortcut.TargetPath=""%~dp0Notepad++.exe"":Shortcut.WorkingDirectory=""%~dp0"":Shortcut.Save:close")
    
12.     exit/b

复制代码

三重语境 bat+vbs+mshta  会使 vbs 处理双引号 '雪上加霜'，而用 jscript 平替 vbs 会轻松得多，虽然也要对路径分隔符 \ 倍加呵护，但很容易在复合语块中走通，见下例

1. @echo off & set "tp=%~dp0Notepad++.exe" & set "wd=%~dp0"
   
2. if exist "%SystemRoot%\System32\mshta.exe" (
   
3.     start "" /min mshta "javaScript:ws=new ActiveXObject('WScript.Shell'),lnk=ws.CreateShortcut(ws.SpecialFolders('Desktop')+'\\Notepad++.lnk'),lnk.TargetPath='%tp:\=\\%',lnk.workingDirectory='%wd:\=\\%',lnk.Save(),close()"
   
4. )
   
5. exit/b

复制代码

redyear2026

挖了一番陈年习作，居然发现一道奇技淫巧，可为 vbs+mshta 代码在批处复合语块中解围，见下例（尾部加一个转义符 ^）

1. @echo off
   
2. if exist "%SystemRoot%\System32\mshta.exe" (
   
3.     start "" /min mshta.exe VBScript:Execute("Set WshShell=CreateObject(""WScript.Shell""):Set Shortcut=WshShell.CreateShortcut(WshShell.SpecialFolders(""Desktop"") & ""\Notepad++.lnk""):Shortcut.TargetPath=""%~dp0Notepad++.exe"":Shortcut.WorkingDirectory=""%~dp0"":Shortcut.Save:close"^)
   
4. )
   
5. exit/b

复制代码

窄口牛

对ps一点都不懂，所以无法帮你，抱歉。

bfgxp

Anson4 发表于 2026-3-20 18:36
那个小工具是不是 Shortcut？

scut.exe，一个13kb的小工具

juiceV5

不错不错

Anson4

redyear2026 发表于 2026-3-20 21:57
挖了一番陈年习作，居然发现一道奇技淫巧，可为 vbs+mshta 代码在批处复合语块中解围，见下例（尾部加一个 ...

经测试，这个方法简单有效，感谢回复！

Anson4

redyear2026 发表于 2026-3-20 20:41
在批处脚本中，mshta 代码落入圆括号这类复合语块里，据说会有一个 '禁则'，即不能出现嵌套双引号或嵌套单 ...

方案1之前就曾测试过，可行，但没保持嵌套，所以没有采用。
方案2，测试出错。

redyear2026

Anson4 发表于 2026-3-21 14:36
方案1之前就曾测试过，可行，但没保持嵌套，所以没有采用。
方案2，测试出错。 ...

10楼方案2代码已经订正，错打了几个字符，应该可以了。

小透明

我是改用cmd套powershell这样的了：

1. powershell -NoProfile -ExecutionPolicy Bypass -Command "$s=(New-Object -ComObject WScript.Shell).CreateShortcut([System.Environment]::GetFolderPath('Desktop') + '\Internet Download Manager.lnk'); $s.TargetPath='%~dp0IDMan.exe'.Replace('\\','\'); $s.WorkingDirectory='%~dp0'.Replace('\\','\'); $s.Save()"

复制代码

效果和原来差不多，SpecialFolder给出的目录也和原来使用mshta差不多

BEIKING

鱼总，新系统 mshta 不能用，WScript 和 CScript 也不能用吗，只要这两个能用，可以转成 VBS 文件执行嘛，这也是一个方案，我现在就这么干

Anson4

BEIKING 发表于 2026-3-22 10:07
鱼总，新系统 mshta 不能用，WScript 和 CScript 也不能用吗，只要这两个能用，可以转成 VBS 文件执行嘛， ...

听说有些系统VBS用不了了

Anson4

redyear2026 发表于 2026-3-21 18:19
10楼方案2代码已经订正，错打了几个字符，应该可以了。

方案2测试成功
另外有个发现，Windows 11 26H1 有自带 mshta，可是不能用。

redyear2026

Anson4 发表于 2026-3-23 14:57
方案2测试成功
另外有个发现，Windows 11 26H1 有自带 mshta，可是不能用。

只要在系统目录中有 mshta.exe 独立运行*.hta 脚本文件还是可以的，如在命令行运行 mshta abc.hta 应该没问题。系统只是阻截了所谓的 '内嵌' 式调用 mshta 代码，例如在批处脚本中直接运行 mshta VBScript:...，如此也就阻断了过去常用的在批处脚本中直接运行 vbs/jscript 代码的方法，改走创建临时文件 *.vbs, *.js 或混编 bat+jscript, bat+vbs 之道吧...

Anson4

redyear2026 发表于 2026-3-23 17:50
只要在系统目录中有 mshta.exe 独立运行*.hta 脚本文件还是可以的，如在命令行运行 mshta abc.hta 应该没 ...

混编 bat+jscript 就是10楼的方案2吗？

redyear2026

Anson4 发表于 2026-3-23 19:42
混编 bat+jscript 就是10楼的方案2吗？

混编 bat+jscript 版式示例如下，代码存为 *.bat 运行（如 test.bat ），其中第二至第七行是批处代码，第九行开始皆为 jscript 代码，第一和第八行是两种代码的混编分界标识，虽不止一种格式，但本人常用此法。

1. 2>1/* ::
   
2. @echo off &setlocal
   
3. set "cs=\Notepad++.lnk"
   
4. set "tp=%~dp0Notepad++.exe"
   
5. set "wd=%~dp0"
   
6. cscript /nologo /e:jscript "%~f0" "%cs%" "%tp%" "%wd%"
   
7. exit/b
   
8. */
   
9. v=WSH.arguments, ws=WSH.createObject('wscript.shell');
   
10. lnk=ws.CreateShortcut(ws.SpecialFolders('Desktop')+v(0));
    
11. lnk.TargetPath=v(1);
    
12. lnk.workingDirectory=v(2);
    
13. lnk.Save(), WSH.quit();

复制代码

ebaqiang

我也在等楼下回帖