<求助>关于将老毛桃集成补丁脚本更改为繁体以后发生的问题

aiya11

脚本文件更改后如下

@Echo Off
COLOR 2F
TITLE 老毛桃製作的 Windows Hotfix 自動集成工具 。。。
Echo 歡迎使用老毛桃製作的 Windows Hotfix 自動集成工具 。。。
Echo.
Echo 請按任意鍵開始自動集成 Windows 補丁集 。。。
PAUSE>NUL
::設置本程式的配置檔
Set CFGFile=配置檔.ini
::設置本地目錄
For /F "delims=" %%I In ("%CFGFile%") Do Set ThisPath=%%~dpI
Set ThisPath=%ThisPath:~0,-1%
::設置 Windows 安裝源 I386 的父路徑
For /F "tokens=2 delims=^=" %%i In ('find /I ^"安裝源^" %CFGFile%') do SET XPSP2CD=%%i
::設置臨時目錄
Set TempDir=Temp_Files
::設置補丁集檔所在檔夾
For /F "tokens=2 delims=^=" %%i In ('find /I ^"Hotfix文件夾^" %CFGFile%') do SET SP2HotFix=%%i
::設置最終集成後的 Windows 安裝檔夾
Set SP2_HotFixCD=%ThisPath%\WinXP_HotFixed_CD
Set MCAB=MAKECAB /D CompressionType=LZX /D CompressionMemory=21
If Not Exist "%XPSP2CD%\I386" (
Echo.
Echo 在您指定的 Windows 安裝源中沒有找到相關檔，
Echo 請修改 %CFGFile% 後重新運行本程式
Echo.
Echo 請按任意鍵退出程式！
PAUSE>NUL
Exit
)

::準備自動集成
Echo.
Echo 正在準備自動集成 。。。
TITLE 正在準備自動集成 。。。
If Exist "%SP2_HotFixCD%" RD /S /Q "%SP2_HotFixCD%"
If Exist %TempDir% RD /S /Q %TempDir%
If Exist DOSNET.INF Del DOSNET.INF /Q>NUL 2>NUL
If Exist TXTSETUP.SIF Del TXTSETUP.SIF /Q>NUL 2>NUL
MD %TempDir%

::複製 Windows 安裝檔
Echo.
Echo 正在複製 Windows 安裝檔 。。。
TITLE 正在複製 Windows 安裝檔 。。。
XCOPY /E /I /V "%XPSP2CD%" "%SP2_HotFixCD%"
Ren "%SP2_HotFixCD%\i386\HIVESYS.INF" HIVESYS.BAK
If Exist HIVESYS_404.INF Copy "HIVESYS_404.INF" "%SP2_HotFixCD%\i386\HIVESYS.INF" /Y>NUL 2>NUL

::替換 DOTNET 元件安裝檔
For /F "tokens=2 delims=^=" %%i In ('find /I ^"替換DOTNETFX^" %CFGFile%') do SET DOTNETFX=%%i
For /F "tokens=2 delims=^=" %%i In ('find /I ^"DOTNET3文件夾^" %CFGFile%') do SET DOTNET3=%%i
If Not "DOTNETFX%DOTNETFX%"=="DOTNETFX1" Goto DOTNETSKIP
Echo.
Echo 正在替換 .NET Framework 安裝檔 。。。
TITLE 正在替換 .NET Framework 安裝檔 。。。
If Exist "%SP2_HotFixCD%\DOTNETFX" Del "%SP2_HotFixCD%\DOTNETFX\*.*" /Q>NUL 2>NUL&&Copy %DOTNET3%\*.* "%SP2_HotFixCD%\DOTNETFX\" /Y>NUL 2>NUL
Echo .NET Framework 安裝文件替換完畢
:DOTNETSKIP

::集成 Windows Media Player
For /F "tokens=2 delims=^=" %%i In ('find /I ^"WMP集成^" %CFGFile%') do SET AddWMP=%%i
If Not "AddWMP%AddWMP%"=="AddWMP1" Goto WMPSKIP
Echo.
Title 正在集成 Windows Media Player 。。。
For /F "tokens=2 delims=^=" %%i In ('find /I ^"集成WMP版本^" %CFGFile%') do SET AddWMPVer=%%i
If "AddWMPVer%AddWMPVer%"=="AddWMPVer10" Goto WMP10
If "AddWMPVer%AddWMPVer%"=="AddWMPVer11" Goto WMP11
Goto WMPSKIP
:WMP10
Echo 正在集成 Windows Media Player 10 。。。
For /F "tokens=2 delims=^=" %%i In ('find /I ^"WMP10文件夾^" %CFGFile%') do SET WMP10Folder=%%i
For /F %%i In ('dir /B %WMP10Folder%\*.EXE') do START /WAIT %WMP10Folder%\%%i /T:"%ThisPath%\%TempDir%" /Q /C
MOVE /Y %TempDir%\*.CAT %WMP10Folder%>NUL 2>NUL
Set DelWMP10File=audiodev.dll,syncpl??.wpl,drmupgds.exe,wpd*.*,wmpe*.*,wmdrm*.dll,msoobci.dll,uWDF.exe,wdf*.*,wmlaunch.exe
Set DelWMP10File=%DelWMP10File%,wmpsrcwp.dll,wmsetsdk.exe,wmvadv*.dll,*.acm,*.chm,*.inf,*.png,*.txt,*.wmz,*.xml
pushd %TempDir%
For %%i In (%DelWMP10File%) Do If Exist %%i Del %%i /Q>NUL 2>NUL
popd
Set WMPReplace=ASFERROR.DL_,BLACKBOX.DL_,CEWMDM.DL_,CUSTSAT.DL_,DRMCLIEN.DL_,DRMSTOR.DL_,DRMV2CLT.DL_,LAPRXY.DL_
Set WMPReplace=%WMPReplace%,LOGAGENT.EX_,MIGRATE.EX_,MPVIS.DL_,MSNETOBJ.DL_,MSPMSNSV.DL_,MSPMSP.DL_,MSSCP.DL_,MSWMDM.DL_
Set WMPReplace=%WMPReplace%,PLYLST1.WP_,PLYLST10.WP_,PLYLST11.WP_,PLYLST12.WP_,PLYLST13.WP_,PLYLST14.WP_,PLYLST15.WP_
Set WMPReplace=%WMPReplace%,PLYLST2.WP_,PLYLST3.WP_,PLYLST4.WP_,PLYLST5.WP_,PLYLST6.WP_,PLYLST7.WP_,PLYLST8.WP_
Set WMPReplace=%WMPReplace%,PLYLST9.WP_,QASF.DL_,SETUP_WM.EX_,UNREGMP2.EX_,WMADMOD.DL_,WMADMOE.DL_,WMASF.DL_,WMDMLOG.DL_
Set WMPReplace=%WMPReplace%,WMDMPS.DL_,WMERROR.DL_,WMIDX.DL_,WMNETMGR.DL_,WMP.DL_,WMP.OC_,WMPASF.DL_,WMPBAND.DL_,WMPCD.DL_
Set WMPReplace=%WMPReplace%,WMPCORE.DL_,WMPDXM.DL_,WMPLAYER.AD_,WMPLAYER.EX_,WMPLOC.DL_,WMPSHELL.DL_,WMPUI.DL_,WMSDMOD.DL_
Set WMPReplace=%WMPReplace%,WMSDMOE2.DL_,WMSPDMOD.DL_,WMSPDMOE.DL_,WMVCORE.DL_,WMVDMOD.DL_,WMVDMOE2.DL_
For %%i In (%WMPReplace%) Do If Exist "%SP2_HotFixCD%\i386\%%i" Del "%SP2_HotFixCD%\i386\%%i" /Q>NUL 2>NUL
MOVE /Y "%TempDir%\*.*" "%SP2_HotFixCD%\i386\">NUL 2>NUL
Goto WMPFinished
:WMP11
Echo 正在集成 Windows Media Player 11 。。。
For /F "tokens=2 delims=^=" %%i In ('find /I ^"WMP11文件夾^" %CFGFile%') do SET WMP11Folder=%%i
For /F %%i In ('dir /B %WMP11Folder%') do START /WAIT %WMP11Folder%\%%i /T:"%ThisPath%\%TempDir%" /Q /C
start /WAIT %TempDir%\umdf.exe /S:"%SP2_HotFixCD%\" /PASSIVE /QUIET
start /WAIT %TempDir%\WindowsXP-MSCompPackV1-x86.exe /S:"%SP2_HotFixCD%\" /PASSIVE /QUIET
start /WAIT %TempDir%\wmpappcompat.exe /S:"%SP2_HotFixCD%\" /PASSIVE /QUIET
start /WAIT %TempDir%\wmfdist11.exe /S:"%SP2_HotFixCD%\" /PASSIVE /QUIET
start /WAIT %TempDir%\wmp11.exe /S:"%SP2_HotFixCD%\" /PASSIVE /QUIET
move /Y "%SP2_HotFixCD%\i386\i386\msdelta.dll" "%SP2_HotFixCD%\i386\">NUL 2>NUL&&RD /Q "%SP2_HotFixCD%\i386\i386\"
>>"%SP2_HotFixCD%\i386\txtsetup.sif" Echo.
>>"%SP2_HotFixCD%\i386\txtsetup.sif" Echo [SourceDisksFiles]
>>"%SP2_HotFixCD%\i386\txtsetup.sif" Echo wmdrmsdk.dll = 100,,,,,,,2,0,0
>>"%SP2_HotFixCD%\i386\txtsetup.sif" Echo mfplat.dll   = 100,,,,,,,2,0,0
>>"%SP2_HotFixCD%\i386\txtsetup.sif" Echo.
Del %TempDir%\*.* /Q>NUL 2>NUL
:WMPFinished
Echo Windows Media Player %AddWMPVer% 集成完畢
:WMPSKIP

::集成 Windows 補丁
Echo.
Title 正在集成 Windows 補丁集 。。。
For /F %%i In ('dir /B /OD %SP2HotFix%\*.exe') DO ECHO 正在集成 %%i&&START /WAIT %SP2HotFix%\%%i /S:"%SP2_HotFixCD%\" /PASSIVE /QUIET

::壓縮集成後生成的新檔
Echo.
Echo 正在壓縮補丁集成後的新檔 。。。
TITLE 正在壓縮補丁集成後的新檔 。。。
::若存在 LANG\IMEKR61.IME 則壓縮之
If Exist "%SP2_HotFixCD%\I386\LANG\imekr61.ime" %MCAB% /L "%SP2_HotFixCD%\I386\LANG" "%SP2_HotFixCD%\I386\LANG\imekr61.ime"&&Del "%SP2_HotFixCD%\I386\LANG\imekr61.ime" /Q>NUL 2>NUL
::將原 HIVESYS.INF 替換掉暫存檔案
Del "%SP2_HotFixCD%\i386\HIVESYS.INF" /Q>NUL 2>NUL
Ren "%SP2_HotFixCD%\i386\HIVESYS.BAK" HIVESYS.INF
::使用原版的 Windows 安裝協定檔
If Exist "%XPSP2CD%\I386\EULA.TXT" Copy "%XPSP2CD%\I386\EULA.TXT" "%SP2_HotFixCD%\i386\" /Y>NUL 2>NUL
::如果有 I386\Update 目錄，則轉移其中的檔並刪除此目錄
If Exist "%SP2_HotFixCD%\i386\update" MOVE /Y "%SP2_HotFixCD%\i386\update\*.*" "%SP2_HotFixCD%\I386">NUL 2>NUL&&RD /S /Q "%SP2_HotFixCD%\I386\update\"
::將 TXTSETUP.SIF 轉移出來
If Exist "%SP2_HotFixCD%\I386\txtsetup.sif" MOVE /Y "%SP2_HotFixCD%\i386\txtsetup.sif" .\>NUL 2>NUL
If Exist "%SP2_HotFixCD%\i386\WINNT.SIF" Copy "%SP2_HotFixCD%\i386\WINNT.SIF" .\WINNT.TMP /Y>NUL 2>NUL&&Del "%SP2_HotFixCD%\i386\WINNT.SIF" /Q>NUL 2>NUL
::將所有新檔移動到臨時目錄以備壓縮
For %%i In (^"%XPSP2CD%\I386\ntldr^") Do Set FileDate=%%~ti
For /F "tokens=1" %%i In ("%FileDate%") Do Set FileDate=%%i
For /F "tokens=4" %%i In ('dir /A-D /4 ^"%SP2_HotFixCD%\I386^" ^|find /V ^"%FileDate%^"') do IF EXIST "%SP2_HotFixCD%\I386\%%i" move "%SP2_HotFixCD%\I386\%%i" "%TempDir%">NUL 2>NUL
::將 TXTSETUP.SIF 放回 I386 目錄
If Exist txtsetup.sif MOVE /Y txtsetup.sif "%SP2_HotFixCD%\i386">NUL 2>NUL
::如果存在應答檔則複製到 I386 下
If Exist WINNT.SIF Copy WINNT.SIF "%SP2_HotFixCD%\I386" /Y>NUL 2>NUL
If Exist WINNT.TMP Copy WINNT.TMP "%SP2_HotFixCD%\i386\WINNT.SIF" /Y>NUL 2>NUL&&Del WINNT.TMP /Q>NUL 2>NUL
::將已壓縮過的檔返回 I386 目錄
MOVE /Y %TempDir%\*.??_ "%SP2_HotFixCD%\I386">NUL 2>NUL
::不壓縮 TELNET.EXE，轉移至 I386 目錄
::If Exist %TempDir%\TELNET.EXE MOVE /Y %TempDir%\TELNET.EXE "%SP2_HotFixCD%\I386">NUL 2>NUL
::如果集成了 WMP10，則將相關的安全編目檔放到 SVCPACK 目錄，並在 SVCPACK.INF 中註冊之
If "%AddWMPVer%"=="10" DIR /B "%WMP10Folder%\*.CAT">>"%TempDir%\SVCPACK.INF"&&Move /Y "%WMP10Folder%\*.CAT" "%SP2_HotFixCD%\I386\SVCPACK">NUL 2>NUL
::將 DOSNET.INF 從臨時目錄移出來以備修復
If Exist %TempDir%\DOSNET.INF MOVE /Y %TempDir%\DOSNET.INF .\>NUL 2>NUL
::將剩餘在臨時目錄中的所有新檔壓縮並刪除未壓縮版本
For /F %%i In ('dir /B %TempDir%') do %MCAB% /L %TempDir% %TempDir%\%%i&&del %TempDir%\%%i /Q>NUL 2>NUL
::將壓縮過的新檔移動到 I386 中
MOVE /Y %TempDir%\*.* "%SP2_HotFixCD%\I386">NUL 2>NUL

::刪除無用檔
Echo HotFix 集成完畢！正在刪除無用的檔 。。。
::刪除臨時目錄
RD /S /Q %TempDir%
::按配置檔中的保留檔清單保留 SVCPACK 檔夾中的檔
For /F "tokens=1 delims=:" %%i In ('findstr /N /B "\[保留檔\]" %CFGFile%') do set KeepLins=%%i
For /F "eol=; tokens=1 skip=%KeepLins% usebackq" %%i In ("%CFGFile%") Do If Exist "%SP2_HotFixCD%\i386\SVCPACK\%%i.EXE" Ren "%SP2_HotFixCD%\i386\SVCPACK\%%i.EXE" %%i.BAK>NUL 2>NUL
::刪除 SVCPACK 檔夾中的無用檔
Del "%SP2_HotFixCD%\i386\SVCPACK\*.EXE" /Q>NUL 2>NUL
If Exist "%SP2_HotFixCD%\i386\SVCPACK\HFINT.DAT" Del "%SP2_HotFixCD%\i386\SVCPACK\HFINT.DAT" /Q>NUL 2>NUL
If Exist "%SP2_HotFixCD%\i386\SVCPACK\branches.inf" Del "%SP2_HotFixCD%\i386\SVCPACK\branches.inf" /Q>NUL 2>NUL
Ren "%SP2_HotFixCD%\i386\SVCPACK\*.BAK" *.EXE
::如果設置了不保留 Win9X 升級安裝 WinXP 的功能，則刪除相關檔夾
For /F "tokens=2 delims=^=" %%i In ('find /I ^"Win9X保留^" %CFGFile%') do SET Keep9X=%%i
If Not "Keep9X%Keep9X%"=="Keep9X1" (
If Exist "%SP2_HotFixCD%\i386\WIN9XMIG" RD /S /Q "%SP2_HotFixCD%\i386\WIN9XMIG"
If Exist "%SP2_HotFixCD%\i386\WIN9XUPG" RD /S /Q "%SP2_HotFixCD%\i386\WIN9XUPG"
)

::最終校驗一下可能存在的相同檔
Echo.
Echo 正在最後校驗相同檔 。。。
TITLE 正在最後校驗相同檔 。。。
For /F %%i In ('dir /B ^"%SP2_HotFixCD%\I386\LANG^"') DO IF EXIST "%SP2_HotFixCD%\I386\%%i" COPY "%SP2_HotFixCD%\I386\LANG\%%i" "%SP2_HotFixCD%\I386" /Y>NUL 2>NUL

::修復 DOSNET.INF 文件
Echo.
Echo 修復 DOSNET.INF 文件 。。。
TITLE 修復 DOSNET.INF 文件 。。。
If Exist DOSNET.TMP Del DOSNET.TMP /Q>NUL 2>NUL
For /f "tokens=4 delims=_" %%i In ('findstr ^"EULAID^" ^"%SP2_HotFixCD%\I386\EULA.TXT^"') do SET EULAID=%%i
::If "EULAID%EULAID%"=="EULAIDOEM" (Set IMEKR61=d5,I386\LANG\imekr61.ime) Else (Set IMEKR61=d1,LANG\imekr61.ime)
Set IMEKR61=d5,I386\LANG\imekr61.ime
SETLOCAL ENABLEDELAYEDEXPANSION
For /F "tokens=1* delims=:" %%i In ('findstr /N .* DOSNET.INF') do (
    Set str=%%j
    If Not "!str!"=="" Set "str=!str:d1,imekr61.ime=%IMEKR61%!"
    If Not "!str!"=="" Set "str=!str:d5,I386\wmdrmsdk.dll=d1,wmdrmsdk.dll!"
    If Not "!str!"=="" Set "str=!str:d5,I386\MFPLAT.dll=d1,MFPLAT.dll!"
    If Not "!str!"=="" Set "str=!str:d1,update\updspapi.dll=d1,updspapi.dll!"
    If Not "!str!"=="" Set "str=!str:d1,update\update.exe=d1,update.exe!"
    If Not "!str!"=="" Set "str=!str:d1,update\spcustom.dll=d1,spcustom.dll!"
    Echo.!str!>>DOSNET.TMP
)
ENDLOCAL
If Exist DOSNET.INF Del DOSNET.INF /Q>NUL 2>NUL&&Ren DOSNET.TMP DOSNET.INF
If Exist DOSNET.INF MOVE /Y DOSNET.INF "%SP2_HotFixCD%\I386\">NUL 2>NUL

::集成完畢
Echo.
Echo 集成補丁完畢，正在製作光碟鏡像檔 。。。
TITLE 集成補丁完畢，正在製作光碟鏡像檔 。。。
For /F "tokens=2 delims=^=" %%i In ('find /I ^"自動生成ISO^" %CFGFile%') do SET AutoCube=%%i
If Not AutoCube%AutoCube%==AutoCube1 Goto NoCube
For /F "tokens=2 delims=^=" %%i In ('find /I ^"鏡像檔案名^" %CFGFile%') do SET ImageName=%%i
For /F "tokens=2 delims=^=" %%i In ('find /I ^"鏡像ISO標籤^" %CFGFile%') do SET ImageVol=%%i
For /F "tokens=2 delims=^=" %%i In ('find /I ^"檔創建日期^" %CFGFile%') do SET ImageFileDate=%%i
cdimage.exe -l"%ImageVol%" -t%ImageFileDate% -h -n -bXP_CD.BIN -x -o -oc -oi -m "%ThisPath%\WinXP_HotFixed_CD" "%ImageName%"
Goto Cubed
:NoCube
TITLE 集成補丁完畢
Echo.
Echo 所有補丁已經集成完畢，感謝您的使用！
Echo 請按任意鍵退出程式 。。。
Goto Exit
:Cubed
TITLE 全部完成！
Echo 所有補丁已集成，新的 ISO 檔已經製作完畢，請測試。感謝您的使用！
Echo.
Echo 請按任意鍵退出程式 。。。
Goto Exit
:Exit
PAUSE>NUL
Exit

以上脚本中我将hivesys.inf中对应的install_language=804  更改为了404

配置文件内容没有更改。配置文件的名称由word翻译成 配置檔 ,名字最后为  配置檔.ini

[警告]
;此檔為 Hotfix 自動集成程式的配置檔，文本格式不能有任何
;修改，本配置檔的注釋是為了便於理解，不能隨便刪除、修改！

[基本設置]
;指定 Windows 安裝檔夾 I386 的父目錄，支援中文、長檔夾名
;包含空格的路徑兩邊不需要添加引號，最後也不允許有“\”存在。
安裝源  =F:
;此處設置的是 WinXP 的補丁檔存放路徑，它須與本配置檔平級
;此檔夾名稱不建議使用中文名或含有空格的名稱
Hotfix文件夾 =Hotfix_Files
;是否集成 Windows Media Player，是就設置為 1，否則設置為 0
WMP集成  =0
;如果集成 WMP，希望集成那個版本，只支持 10 和 11 兩個值
集成WMP版本 =10
;如果集成 WMP10，請指定檔夾，並將 WMP10 的安裝檔放入
;集成 WMP10 的話，目前有兩個 WMP10 的補丁，需要下載它們，
;並將這兩個基於 WMP10 的補丁放到指定的 Hotfix 檔夾中去
WMP10文件夾 =WMP10_Files
;如果集成 WMP11，請指定檔夾，並將 WMP11 的安裝檔放入
WMP11文件夾 =WMP11_Files
;是否保留 Win9X 下升級安裝 WinXP 的功能，建議不保留以節省空間
Win9X保留 =0
;是否以 .NET Framework 3.0 替換掉原版中的 .NET Framework 1.1
替換DOTNETFX =1
;此檔夾用來存放 .NET Framework 3.0 及其語言包的安裝檔
DOTNET3文件夾 =DOTNETFX
;此處設置為是否自動生成 ISO 鏡像檔，以及鏡像的一些細節設置
自動生成ISO =1
鏡像檔案名 =VRMPVOL_CN_Hotfix.ISO
鏡像ISO標籤 =VRMPVOL_CN
檔創建日期 =11/29/2006,12:00:00

[保留檔]
;補丁集成後，I386\SVCPACK中仍需保留的可執行檔
;因為這些檔刪除的話，補丁可能會沒有正確安裝上
;只需要在下列清單中寫上補丁檔案名中的數位即可。
KB885836
KB890859
KB891781
KB898461
KB900485
KB908531
KB911562
KB916595
KB920213
KB920872
KB923689
KB925454


然后在繁体系统中运行 在 自动集成.cmd
最后运行过程中
1.文件复制正常
2.补丁集成  (显示很快，不停闪烁，查看系统spslpsrm.log，显示

0.000: ================================================================================
0.047: 2007/04/16 10:29:34.078 (local)
0.047: e:\bddc4e8f6f6b6b93d8ca52f1d584\update\update.exe (version 5.5.33.0)
0.047: Slipstream mode
0.047: Service Pack 用以下指令行啟動: /S:"E:\Tools\WinXP_Hotfix_WMP\WinXP_HotFixed_CD\" /PASSIVE /QUIET
0.094: Package Type:  BRANCHING.
0.391: GetTargetOSLanguage:  Error 0x2 while trying to retrieve target OS language information from E:\Tools\WinXP_Hotfix_WMP\WinXP_HotFixed_CD\.
0.391: GetTargetOSInformation:  Error determining language:  GLE = 0x2
0.391: IntegrateHotfix:  Error 0x2 while gathering information about target E:\Tools\WinXP_Hotfix_WMP\WinXP_HotFixed_CD\.
0.407: 安裝程式找不到您要與這個軟體更新封裝整合的發佈資料夾，/integrate 參數要求到發佈資料夾的完整路徑。
0.407: 安裝程式找不到您要與這個軟體更新封裝整合的發佈資料夾，/integrate 參數要求到發佈資料夾的完整路徑。)

所有补丁一个都没有打上。
3.修復 DOSNET.INF 文件，(提示找不到DOSNET.INF文件)


正在壓縮補丁集成後的新檔 。。。
HotFix 集成完畢！正在刪除無用的檔 。。。
這個時候不應有  usebackq"。
系統找不到指定的檔案。
正在最後校驗相同檔 。。。
修復 DOSNET.INF 文件 。。。
FINDSTR: 無法開啟 DOSNET.INF

上面这段就是显示出来的问题

帮忙看看什么问题

[ 本帖最后由 aiya11 于 2007-4-16 12:33 PM 编辑 ]