|
|
发表于 2026-10-17 21:20:11
|
显示全部楼层
@echo off
title 自定义重置系统安装日期
setlocal EnableDelayedExpansion
cacls.exe "%SystemDrive%\System Volume Information" >nul 2>nul
IF %errorlevel%==0 GOTO Admin
fltmc >nul||mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~dpnx0","%*",,"runas",1)(window.close)&&exit
:Admin
echo 命令行调用参数格式: YYYY-MM-DD HH:MM:SS
set "DatePart=%1"
set "TimePart=%2"
if "%~1"=="" (
echo.
set /p DatePart=请输入要重置的系统安装日期^(回车默认为当前日期^):
set /p TimePart=请输入要重置的系统安装时间^(回车默认为当前时间^):
for /f "tokens=2 delims==" %%a in ('wmic os get localdatetime /value') do set dt=%%a
if "!DatePart!"=="" set "DatePart=!dt:~0,4!-!dt:~4,2!-!dt:~6,2!"
if "!TimePart!"=="" set "TimePart=!dt:~8,2!:!dt:~10,2!:!dt:~12,2!"
)
echo.
echo ==========================================
echo 重置系统安装日期为 !DatePart! !TimePart!
echo ==========================================
echo.
for /f "usebackq tokens=1,2 delims=|" %%a in (`powershell -NoProfile -Command "$d = [DateTime]::Parse('!DatePart! !TimePart!'); $utc = $d.ToUniversalTime(); $unix = [uint32](($utc - [DateTime]::new(1970,1,1,0,0,0,[DateTimeKind]::Utc)).TotalSeconds); $ft = [uint64]$utc.ToFileTimeUtc(); Write-Output ($unix.ToString() + '|' + $ft.ToString())"`) do (
set "WriteDate=%%a"
set "WriteTime=%%b"
)
if not defined WriteDate (
echo [错误] 时间戳计算失败,请检查日期时间格式。
pause
exit /b 1
)
set "RegKey=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"
echo 写入 InstallDate = !WriteDate! ^(Unix 时间戳^)
reg add "%RegKey%" /v InstallDate /t REG_DWORD /d !WriteDate! /f /reg:64 >nul
if errorlevel 1 (
echo [错误] 写入 InstallDate 失败。
pause
exit /b 1
)
echo 写入 InstallTime = !WriteTime! ^(LDAP/FILETIME 时间戳^)
reg add "%RegKey%" /v InstallTime /t REG_QWORD /d !WriteTime! /f /reg:64 >nul
if errorlevel 1 (
echo [错误] 写入 InstallTime 失败。
pause
exit /b 1
)
for /f "tokens=2 delims==" %%a in ('wmic os get installdate /value') do set st=%%a
echo.
echo ==========================================
echo 当前系统安装日期为 %st:~0,4%-%st:~4,2%-%st:~6,2% %st:~8,2%:%st:~10,2%:%st:~12,2%
echo ==========================================
echo.
pause
exit /b 1 |
|