|
|
发表于 2015-4-16 16:55:45
|
显示全部楼层
@echo off
color 0a
Title Wim_RAMOS_64位系统热备份工具（2013-4-23）
rem 开打变量延时，否则下面的功能可能不能实现
setlocal enabledelayedexpansion
rem 设置内存系统盘符
set SrcDrv=C:
rem 设置热备份缓存目录
set DstDrv=H:\WimRamOS
rem 设置WIM文件位置（若文件不存在热备份将自动生成，若存在热备份将以追加卷方式备份）
set WimPath=H:\WimRamOS.wim
rem 设置备份系统所使用用户名_用于备份
set Usersbak=Administrator
rem 主要处理的系统目录
set ProgramPath=\Program Files\
set x86Path=\Program Files (x86)\
set WindowsPath=\WINDOWS\
set UsersPath=\Users\
set PDPath=\ProgramData\
echo ############################################################################
echo # Wim_RAMOS_64位系统热备份工具 #
echo # #
echo # 说明：本工具默认热备份%SrcDrv%盘系统到%DstDrv%目录，并将%DstDrv%目录 #
echo # #
echo # 已添加卷方式打包进%WimPath%，添加完成后下次重启便是从新备份的 #
echo # #
echo # 分卷启动。若您想自定义以上各路径，请编辑本批处理内开头的环境变量。 #
echo # #
echo #（添加卷方式打包WIM的好处是备份速度快，并且WIM内保存了每次备份的数据， #
echo # #
echo # 必要时可以方便的恢复到备份前的系统！缺点是WIM体积会稍大， #
echo # #
echo # 但可以用WimTool工具导出需要的分卷启动！这样体积就小了） #
echo ############################################################################
echo ***按任意键开始热备份***退出热备份请直接关掉本窗口***
pause >nul
net stop sppsvc
echo ***开始按设定复制文件,这可能需要一些时间，请耐心等待...
FastCopy.exe /cmd=diff /auto_close /force_close /open_window /estimate /log /speed=full /disk_mode=auto /acl "%SrcDrv%%ProgramPath%" "%SrcDrv%%x86Path%" "%SrcDrv%%WindowsPath%" "%SrcDrv%%UsersPath%" "%SrcDrv%%PDPath%" /to="%DstDrv%\"
echo.
echo ***处理与热备份Windows注册表文件***
Reg delete HKLM\SYSTEM\mounteddevices /v "\DosDevices\%SrcDrv%" /f
Reg save HKLM\COMPONENTS %DstDrv%\Windows\system32\config\COMPONENTS /y
Reg save HKLM\system %DstDrv%\Windows\system32\config\SYSTEM /y
Reg save HKLM\software %DstDrv%\Windows\system32\config\SOFTWARE /y
Reg save HKU\.DEFAULT %DstDrv%\Windows\system32\config\DEFAULT /y
Reg save HKLM\SAM %DstDrv%\Windows\system32\config\SAM /y
Reg save HKLM\SECURITY %DstDrv%\Windows\system32\config\SECURITY /y
Reg save HKCU %DstDrv%\Users\%Usersbak%\NTUSER.DAT /Y
reg save HKCU\software\classes %DstDrv%\Users\%Usersbak%\AppData\Local\Microsoft\Windows\UsrClass.dat /y
REG SAVE HKU\S-1-5-19 %DstDrv%\Windows\ServiceProfiles\LocalService\NTUSER.DAT /y
REG SAVE HKU\S-1-5-20 %DstDrv%\Windows\ServiceProfiles\NetworkService\NTUSER.DAT /y
REG LOAD HKLM\Ram %DstDrv%\Windows\system32\config\SYSTEM
reg add "HKLM\Ram\ControlSet001\Services\Ramdisk" /f /v "Start" /t REG_DWORD /d 0
reg unload HKLM\Ram
del /q /a /f /s %DstDrv%\Windows\System32\config\*.LOG* >nul
RD /s /q %DstDrv%\ProgramData\Templates >nul
RD /s /q %DstDrv%\Users\%Usersbak%\AppData\Local\Temp >nul
echo ############################################################################
echo. 打包Wim文件说明
echo.
echo. 若%WimPath%文件存在，将已添加卷方式打包Wim。（速度快）
echo.
echo. 若%WimPath%文件不存在，将创建一个%WimPath%文件。（速度慢）
echo.
echo ############################################################################
echo ***按任意键开始打包Wim文件***过程可能会很慢请您耐心等待，不要关闭本窗口***
pause >nul
if exist %WimPath% imagex /boot /append %DstDrv% %WimPath% "%date% %time%"
if not exist %WimPath% imagex /boot /capture /compress maximum %DstDrv% %WimPath% "%date% %time%"
echo 备份全部完成，按任意键退出
pause >nul
这个无线网络密码无法备份 |
|
闽公网安备35020302032614号 )
IP卡
狗仔卡
显身卡