|
|
发表于 2019-1-10 09:58:28
|
显示全部楼层
本帖最后由 liuzhaoyzz 于 2019-1-17 15:16 编辑
用楼主的v6.5版本1.14MB的批处理,搭配立邦电子699MB的17763网络版,UEFI-WIN8.1、WIN10x64均制作成功,计算磁盘总空间、已用空间太慢了!提示写引导成功,实际写引导失败,楼主说的找bcd怎样怎样难,我还是直接上个写引导的代码吧!用楼主的程序制作,对于UEFI+MBR硬盘启动的情况,启动分区必须先在磁盘管理中挂载,然后用下面的代码写引导即可,或者直接下载本楼层656楼http://bbs.wuyou.net/forum.php?m ... &fromuid=298214的附件。
WIN8.1开始菜单右键无效;WIN10开始菜单、托盘区wifi和喇叭左键单击无效。这些都是遗留的老问题了,只要上了ms-ramdisk,就有这些毛病,不再细说。这个方案,做成之后和员外的那个R IMG FBWF COMPACT1.2效果是一样的,员外的成功率高,全自动,区别就是一个是img,一个是vhd;楼主的批处理对PE要求较高,不是随便一个PE下就能用的。总体来说受制于r驱加载限制,局限性太大,都属于该遗弃的方案。
@echo off
title Compacted VHD RamDisk OS v6.5
Setlocal EnableDelayedExpansion
pushd "%~dp0"
:RBCD
BCDeditX86.exe 1>nul 2>nul
set "OSName=RVHD"
set "TargetFile=%~d0\Boot\ram.vhd"
rem 更改vhd所在的路径:
set /p "TargetFile=默认保存到“!TargetFile!”,要更改请输入完整路径:"
set "RDevice=[!TargetFile:~0,2!]!TargetFile:~2!"
rem 如果vhd是MBR分区offset=65536(默认),如果是GPT分区offset=33619968
set offset=65536
:DetectUEFI
for /f %%a in ('reg query "HKLM\HARDWARE\UEFI\ESRT" /s 2^>nul^|find /i "{"') do set "IsEFI=%%a"
if "!IsEFI:~-1!" equ "}" (
set "loader=efi"
rem 以下盘符根据自己的情况自己修改,UEFI+MBR硬盘启动的情况,启动分区必须先在磁盘管理中挂载:
set /p "espdrive=请输入ESP或启动分区所在的盘符(不带冒号,例如C)"
set "bcdedit=bcdedit /store !espdrive!:\efi\microsoft\boot\bcd"
goto next
) else (
set "loader=exe"
set "bcdedit=bcdedit"
goto next
)
:next
echo !bcdedit!
for /f "delims={,} tokens=2" %%a in ('%BCDedit% /create /d "!OSName!" /application osloader') do set "GUID={%%a}"
for /l %%i in (0,1,40) do if "!GUID:~%%i,1!" equ "" set "strlen=%%i" && goto StringLength
:StringLength
if !strlen! neq 38 echo 添加BCD启动项出错 & exit /b
for /f "delims={,} tokens=2" %%a in ('%BCDedit% /create /d "!OSName!" /device') do set "GUIDd={%%a}"
%BCDedit% /set !GUIDd! ramdiskimageoffset !offset!
%BCDedit% /set !GUID! device ramdisk="!RDevice!",!GUIDd!
%BCDedit% /set !GUID! osdevice ramdisk="!RDevice!",!GUIDd!
%BCDedit% /set !GUID! path \Windows\system32\boot\winload.!loader!
%BCDedit% /set !GUID! systemroot \Windows
%BCDedit% /set !GUID! inherit {bootloadersettings}
%BCDedit% /set !GUID! BootStatusPolicy ignoreallfailures
%BCDedit% /set !GUID! BootMenuPolicy legacy
%BCDedit% /set !GUID! BadMemoryAccess no
%BCDedit% /set !GUID! PAE ForceEnable
%BCDedit% /set !GUID! DetectHAL yes
%BCDedit% /set !GUID! NX OptOut
%BCDedit% /displayorder !GUID! /addlast
%BCDedit% /set {default} BootMenuPolicy legacy
echo 请仔细检查写引导是否全部操作完成,如果发现错误请检查\efi\microsoft\boot\bcd盘符以及vhd文件路径是否正确!
pause
exit /b
|
|