专门解包AMD芯片组驱动

chiannet · 发表于昨天 20:14

本帖最后由 chiannet 于 2026-8-16 20:24 编辑

搞了个从exe格式AMD芯片组驱动包提取纯驱动的脚本。各位看官再精炼精炼

复制代码

@Echo Off&Setlocal Enabledelayedexpansion
Set z7=
For /f "Skip=1 Tokens=2,*" %%B in ('Reg Query "HKLM\SOFTWARE\7-Zip" /v "Path" 2^>nul') Do (If Exist "%%C7z.exe" (Set "z7=%%C7z.exe" & Goto :Begin))
Echo.& Echo. 本机未安装 7-zip ？
Goto :end
:Begin
CD /d "%~dp0"
Set "FN="
(
Del AMD_Chipset_Drivers.exe /f /q
For /f "Delims=" %%A in ('Dir "AMD_Chipset_Software_*.exe" /b') Do (
Title 从%%A提取AMD芯片组纯驱动。
Set "FN=%%A"
"%z7%" e "%%A" -y -o".\" "*AMD_Chipset_Drivers.exe"
)
) >nul 2>nul
If Not Defined FN (Echo.& Echo. 当前目录缺失AMD芯片组驱动 exe 格式原包，请到 AMD 官网下载！& Goto :End ) Else (
If Not Exist AMD_Chipset_Drivers.exe (Echo.& Echo. 7-Zip 未抽出内层 exe 文件！ & Goto :End)
)
Set /a TRy=1
:B2
Cls
(
For /f "Delims=" %%d in ('Dir "%temp%\{*}" /A:D /B') Do RD "%temp%\%%d" /S /Q
) >nul 2>nul
Start "" AMD_Chipset_Drivers.exe /a /q
Echo __________________________________________________________________
Echo.&Echo. 请不要关闭 AMD_Chipset_Drivers.exe（包括其弹出的任何提示框）！
Echo __________________________________________________________________
Set /a T=4*%TRy%
Echo.&Echo.&Echo. 如果关闭了它，临时目录下释放的msi文件会被自动清除。
Echo.&Echo.&Echo. 等待解压 AMD_Chipset_Drivers.msi ......
Timeout %T% >nul
Set "P="
For /f "Delims=" %%i in ('Dir "%temp%\{*}" /A:D /B') Do (
If Exist "%Temp%\%%i\AMD_Chipset_Drivers.msi" (
Set "P=%Temp%\%%i"
RD .\AMD_Chipset_Drivers /S /Q >nul 2>nul
Start /WAIT msiexec /a "!P!\AMD_Chipset_Drivers.msi" /qn TARGETDIR="%~DP0AMD_Chipset_Drivers"
Title 从 %FN% 提取AMD芯片组纯驱动成功。
(
(
Set "SRC=AMD_Chipset_Drivers"
RD "!SRC!\program files" /S /Q
For %%u in (rtf txt msi) Do Del "!SRC!\*.%%u" /s /f /q
For %%u in (WTx64 W11x64) Do MD "!SRC!\%%u"
If Exist "!SRC!\Chipset_Software" Set "SRC=!SRC!\Chipset_Software"
Del "!SRC!\*.xml" /S /F /Q
) >nul 2>nul
Echo.& Echo.& Echo. 正在分拣Win10/Win11 驱动文件......
For /f "Delims=" %%x in ('Dir "!SRC!" /B /A:D') Do (
Set /a Has10=0,Has11=0
If Exist "!SRC!\%%x\WTx64" Set /a Has10=1
If Exist "!SRC!\%%x\W11x64" Set /a Has11=1
Set /a HasB=!Has10!+!Has11!
IF !HasB! EQU 2 (
Call :D1D 0000 "%%x" "!SRC!"
) Else (
IF !Has11! EQU 1 (
Call :D1D W11x64 "%%x" "!SRC!"
) Else (
IF !Has10! EQU 1 (
Call :D1D WTx64 "%%x" "!SRC!"
) Else (
Echo %%x 不适用于NT 10.0 ？
)
)
)
If /i "!SRC!"=="AMD_Chipset_Drivers" RD /S /Q "!SRC!\%%x" >nul 2>nul
)
RD /S /Q "AMD_Chipset_Drivers\Chipset_Software" >nul 2>nul
)
Cls
Echo. & Echo. & Echo. 现在可以关闭 AMD_Chipset_Drivers.exe 了！& Echo.
Goto :Cleanup
))
Cls
Echo. AMD_Chipset_Drivers.exe 被提前关闭了吗？
Echo. 请不要在此时刻关闭 AMD_Chipset_Drivers.exe！
if %TRy% Lss 6 (
Title 第 !TRy! 次从提取AMD芯片组纯驱动失败！
Set /a TRy+=1
Goto :B2
)
Echo.& Echo. 很遗憾，经 %TRy% 次尝试从 %FN% 提取AMD芯片组纯驱动都失败了。
:Cleanup
(
Tasklist | Find /i "AMD_Chipset_Drivers.exe" && (Timeout 3 & Goto :Cleanup) || Del AMD_Chipset_Drivers.exe /f /q
If Defined P RD /S /Q "!P!"
) >nul 2>nul
Cls
Echo.&Echo. 成功提取AMD芯片组纯驱动到 "%~DP0AMD_Chipset_Drivers"。
Echo.
:End
Timeout 5 >nul 2>nul
Exit
:D1D
For %%K in (WTx64 W11x64) Do (
If "%~1"=="0000" (Set "P=%%K") Else (Set "P=%~1")
Set /a i=0
For /f "Delims=" %%U in ('Dir "%~3\%~2\!P!\*.inf" /S /B 2^>Nul') Do (Set /a i+=1)
If !i! GTR 0 (
MD "AMD_Chipset_Drivers\%%K\%~2\!P!"
Xcopy "%~3\%~2\!P!" "AMD_Chipset_Drivers\%%K\%~2\!P!" /E /Q /h /R /y
)
) >nul 2>nul
Goto :Eof

复制代码

专门解包AMD芯片组驱动.7z (1.59 KB, 下载次数: 5)

qihua · 发表于昨天 20:53

哇塞厉害了

ZMLoveLH · 发表于昨天 21:33

一款很实用的脚本，多谢分享啊

thyue723 · 发表于昨天 21:49

Intel官网的最新的驱动版本也开始只提供EXE了，现在互联网啥东西都不是那个分享的时代了

527104427 · 发表于昨天 22:13

抓到活的C大

Blacksky · 发表于昨天 22:23

感谢分享辛苦了🌹

a66 · 发表于昨天 23:08

不错的

Anteris · 发表于昨天 23:17

太需要这个了，感谢

it323 · 发表于 4 小时前

收藏备用。

		自动登录	找回密码
密码			注册

[讨论] 专门解包AMD芯片组驱动

评分

浏览过的版块