迅速查看当前内置和外接磁盘全部分区的剩余空间

redyear2026 · 发表于 7 天前

本帖最后由 redyear2026 于 2026-4-23 09:44 编辑

获取磁盘剩余空间的方法有多种，以下的批处代码选用 win 和主流 pe 系统均自带的 fsutil.exe
备注：win11 高版本（25H2）已彻底移除了 wmic 命令行功能

@echo off &if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
setlocal enabledelayedexpansion &set "z=" &for /l %%n in (1,1,16) do set "b= !b!"
for /f "delims=" %%D in ('fsutil fsinfo drives') do set "allD=%%D"
for %%d in (%allD:* =%) do (set "z="
for /f "tokens=2 delims=:(" %%z in ('fsutil volume diskfree %%d') do if not defined z (
set "z=%%z" &set "z=!z: =!" &set "z=!z:,=!"
if "!z:~,1!" geq "1" if "!z:~,1!" leq "9" (set "z=!b!!z!" &set "z=!z:~-16!" &echo,!z!字节 %%d)) )
exit/b

复制代码

有些 pe 系统精简了 fsutil.exe，无法运行以上代码。
以下再给一版批处代码，只用 reg 和 dir 操作，其主要依据是所有盘区根目录下的系统隐藏目录 $RECYCLE.BIN，用此通过 dir /a 定点加速析出所在盘区的剩余空间。
其实，沿用古老的方法 dir x:\ + findstr 对整个盘区根目录处理也可以，只不过一旦遭遇那些 '地大物博' 的根目录，此法会很费时。

@echo off &if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
setlocal enabledelayedexpansion &for /l %%n in (1,1,16) do set "b= !b!"
for /f "tokens=2 delims=\: " %%d in ('reg query HKLM\SYSTEM\MountedDevices^|findstr /i "\\[c-z]:" ') do (
set "z="
for /f "tokens=3 delims= " %%z in ('dir /a/-c "%%d:\$RECYCLE.BIN" 2^>nul') do set "z=%%z"
if defined z set "z=!b!!z!" &set "z=!z:~-16!" &echo,!z!字节 %%d:)
exit/b

复制代码

a66 · 发表于 7 天前

本帖最后由 a66 于 2026-4-22 15:09 编辑

自动遍历电脑所有磁盘（C: D: E:…）
过滤光驱、空盘符、无介质驱动器
输出纯数字剩余字节数
数字自动右对齐，排版整齐
按剩余空间从大到小排序输出

@echo off
:: 顶层注释用 :: 没问题（非循环体）
:: 无参数时脚本自调用，通过管道排序后输出，实现磁盘从大到小排列
if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
:: 启用延迟环境变量扩展，循环中修改变量必须开启
setlocal enabledelayedexpansion
:: 清空变量 z，定义变量 b 为 16 个空格（用于数字右对齐）
set "z=" &for /l %%n in (1,1,16) do set "b= !b!"
:: 获取系统所有磁盘盘符列表
for /f "delims=" %%D in ('fsutil fsinfo drives') do set "allD=%%D"
:: 遍历所有磁盘盘符
for %%d in (%allD:* =%) do (
set "z="
rem 嵌套循环：用 fsutil 查询当前磁盘剩余空间，提取关键数值
for /f "tokens=2 delims=:(" %%z in ('fsutil volume diskfree %%d') do if not defined z (
rem 给变量 z 赋值剩余空间原始数据
set "z=%%z"
rem 去除数值中的所有空格
set "z=!z: =!"
rem 去除数值中的千分位逗号
set "z=!z:,=!"
rem 判断是否为有效数字（过滤光驱、空盘符、无介质驱动器）
if "!z:~,1!" geq "1" if "!z:~,1!" leq "9" (
rem 前面补 16 个空格，实现右对齐效果
set "z=!b!!z!"
rem 截取最后 16 个字符，格式化输出
set "z=!z:~-16!"
rem 输出格式化后的字节数 + 盘符
echo,!z!字节 %%d
)
)
)
:: 退出批处理
exit/b

复制代码

redyear2026 · 发表于 7 天前

a66 发表于 2026-4-22 14:18
自动遍历电脑所有磁盘（C: D: E:…）
过滤光驱、空盘符、无介质驱动器
输出纯数字剩余字节数

阁下再用 ai 解读俺的代码

但按照批处语法规范，循环体内的注释行要用 rem 开头，以免运行出现怪错...

guong · 发表于 7 天前

不错的方案学习了

it323 · 发表于 7 天前

难道这样看很麻烦？

yc2428 · 发表于 7 天前

学习了,谢谢

yyz219195888 · 发表于 7 天前

10 PE 无反应

yyz219195888 · 发表于 7 天前

a66 发表于 2026-4-22 14:18
自动遍历电脑所有磁盘（C: D: E:…）
过滤光驱、空盘符、无介质驱动器
输出纯数字剩余字节数

我的 10 PE 也没有反应

redyear2026 · 发表于 7 天前

yyz219195888 发表于 2026-4-22 18:10
10 PE 无反应

运行一楼代码之前可先在 cmd 窗口命令行测试
where fsutil.exe
查看其返回值是否为一个真实路径文件名，例如
C:\Windows\System32\fsutil.exe
若是，则运行一楼代码应该没问题。

yyz219195888 · 发表于 7 天前

redyear2026 发表于 2026-4-22 19:01
运行一楼代码之前可先在 cmd 窗口命令行测试
where fsutil.exe
查看其返回值是否为一个真实路径文件名 ...

Microsoft Windows [版本 10.0.10586]
(c) 2016 Microsoft Corporation。保留所有权利。

X:\Windows\System32>where fsutil.exe
'where' 不是内部或外部命令，也不是可运行的程序
或批处理文件。

X:\Windows\System32>

无所适从 · 发表于 7 天前

高版本这么坑

redyear2026 · 发表于 7 天前

yyz219195888 发表于 2026-4-22 19:13
Microsoft Windows [版本 10.0.10586]
(c) 2016 Microsoft Corporation。保留所有权利。

再试试如下这一行代码，也要在命令行上跑

for /f %f in ("fsutil.exe") do @echo,%~$path:f

复制代码

如果当前系统已内置 fsutil.exe，其返回值应为其真实路径文件名，否则，说明你的 pe 系统瘦身够狠！

yyz219195888 · 发表于 7 天前

redyear2026 发表于 2026-4-22 20:36
再试试如下这一行代码，也要在命令行上跑

如果当前系统已内置 fsutil.exe，其返回值应为其真实路径文件 ...

Microsoft Windows [版本 10.0.10586]
(c) 2016 Microsoft Corporation。保留所有权利。

X:\Windows\System32>for /f %f in ("fsutil.exe") do @echo,%~$path:f

X:\Windows\System32>

2012飘水 · 发表于 7 天前

感谢分享，体验一下有效

hupoquan · 发表于 7 天前

if ($args.Count -eq 0) {
Get-CimInstance Win32_LogicalDisk | Where-Object { $null -ne $_.FreeSpace } | Sort-Object FreeSpace -Descending | ForEach-Object { "{0,16}字节 {1}:" -f $_.FreeSpace, $_.DriveLetter }
Read-Host
exit 0
}
Get-CimInstance Win32_LogicalDisk | Where-Object { $null -ne $_.FreeSpace } | ForEach-Object { "{0,16}字节 {1}:" -f $_.FreeSpace, $_.DriveLetter }

复制代码

powershell可以用这个代码

redyear2026 · 发表于 6 天前

yyz219195888 发表于 2026-4-22 20:39
Microsoft Windows [版本 10.0.10586]
(c) 2016 Microsoft Corporation。保留所有权利。

一楼代码已更新，可以试试第二版代码。

511307184 · 发表于 6 天前

yyz219195888 发表于 2026-4-22 19:13
Microsoft Windows [版本 10.0.10586]
(c) 2016 Microsoft Corporation。保留所有权利。

非常好！！！！！

yyz219195888 · 发表于 6 天前

redyear2026 发表于 2026-4-23 00:31
一楼代码已更新，可以试试第二版代码。

好的谢谢大神

ebaqiang · 发表于 6 天前

太好啦，萬分感謝版主的無私發佈分享

redyear2026 · 发表于 6 天前

本帖最后由 redyear2026 于 2026-4-23 12:42 编辑

如果极端环境下，目标盘区根目录也没有 $RECYCLE.BIN 这个系统隐藏目录，就只能返回 '远古' 之道了，以下这个版本可用于当前系统没有 fsutil，没有 wmic，没有 powershell，也没有预装那些第三方专用工具的...

@echo off &if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
setlocal enabledelayedexpansion &for /l %%n in (1,1,16) do set "b= !b!"
for /f "tokens=2 delims=\: " %%d in ('reg query HKLM\SYSTEM\MountedDevices^|findstr /i "\\[c-z]:" ') do (
set "z="
for /f "tokens=3 delims= " %%z in ('dir /-c %%d:\^|findstr /eric:"[0-9] 可用字节" ') do set "z=%%z"
if defined z set "z=!b!!z!" &set "z=!z:~-16!" &echo,!z!字节 %%d:) 2>nul
exit/b

复制代码

djsh001 · 发表于 6 天前

it323 发表于 2026-4-22 16:27
难道这样看很麻烦？

这就很清晰了。不必太麻烦。

yszwang · 发表于 6 天前

谢谢楼主分享的好方法

jianwinking · 发表于 6 天前

感谢分享，很多时候没在意空间大小反倒是下载的时候常因空间不足而退出，这个试试

mrzhonghb · 发表于 5 天前

用字节反而不直观，难道要去数位数

redyear2026 · 发表于 5 天前

本帖最后由 redyear2026 于 2026-4-25 10:28 编辑

mrzhonghb 发表于 2026-4-24 21:26
用字节反而不直观，难道要去数位数

限于批处只能玩32位整数计算，也没有再借助外部脚本（如 vbs/jscript/powershell）的大数计算能力，只好用原始字节值了。
非要用批处的拙力鼓捣单位转换（例如转换到 GB 单位），就要有估算的误差，现采用 mb 当量估算，误差大约是 5%，若采用 kb 当量估算，误差会在 2~3%，但遭遇大容量盘区剩余空间，估算值会超限失效。
一旦剩余空间小于1GB，估算值会被被强制为 1GB。

估算为 GB 单位的版本（用20楼代码修订）

@echo off &if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
setlocal enabledelayedexpansion &for /l %%n in (1,1,6) do set "b= !b!"
for /f "tokens=2 delims=\: " %%d in ('reg query HKLM\SYSTEM\MountedDevices^|findstr /i "\\[c-z]:" ') do (
set "z="
for /f "tokens=3 delims= " %%z in ('dir /-c %%d:\^|findstr /eric:"[0-9] 可用字节" ') do set "z=%%z"
if defined z (
set "z=!z:~,-6!" &set/a "z/=1024" &if !z! equ 0 set "z=1"
set "z=!b!!z!" &set "z=!z:~-6!" &echo,!z!GB %%d:) ) 2>nul
exit/b

复制代码

估算为 GB 单位的版本（用一楼代码修订）

@echo off &if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
setlocal enabledelayedexpansion &set "z=" &for /l %%n in (1,1,6) do set "b= !b!"
for /f "delims=" %%D in ('fsutil fsinfo drives') do set "allD=%%D"
for %%d in (%allD:* =%) do (set "z="
for /f "tokens=2 delims=:(" %%z in ('fsutil volume diskfree %%d') do if not defined z (
set "z=%%z" &set "z=!z: =!" &set "z=!z:,=!"
if "!z:~,1!" geq "1" if "!z:~,1!" leq "9" (
set "z=!z:~,-6!" &set/a "z/=1024" &if !z! equ 0 set "z=1"
set "z=!b!!z!" &set "z=!z:~-6!" &echo,!z!GB %%d)) )
exit/b

复制代码

		自动登录	找回密码
密码			注册

[分享] 迅速查看当前内置和外接磁盘全部分区的剩余空间

点评

点评

点评

评分

评分

点评

点评

评分

点评

点评

点评

点评