迅速查看当前内置和外接磁盘全部分区的剩余空间

redyear2026

获取磁盘剩余空间的方法有多种，以下的批处代码选用 win 和主流 pe 系统均自带的 fsutil.exe
备注：win11 高版本（25H2）已彻底移除了 wmic 命令行功能

1. @echo off &if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
   
2. setlocal enabledelayedexpansion &set "z=" &for /l %%n in (1,1,16) do set "b= !b!"
   
3. for /f "delims=" %%D in ('fsutil fsinfo drives') do set "allD=%%D"
   
4. for %%d in (%allD:* =%) do (set "z="
   
5.    for /f "tokens=2 delims=:(" %%z in ('fsutil volume diskfree %%d') do if not defined z (
   
6.      set "z=%%z" &set "z=!z: =!" &set "z=!z:,=!"
   
7.      if "!z:~,1!" geq "1" if "!z:~,1!" leq "9" (set "z=!b!!z!" &set "z=!z:~-16!" &echo,!z!字节 %%d)) )
   
8. exit/b

复制代码

a66

    自动遍历电脑所有磁盘（C: D: E:…）
    过滤光驱、空盘符、无介质驱动器
    输出纯数字剩余字节数
    数字自动右对齐，排版整齐
    按剩余空间从大到小排序输出

1. @echo off
   
2. :: 顶层注释用 :: 没问题（非循环体）
   
3. :: 无参数时脚本自调用，通过管道排序后输出，实现磁盘从大到小排列
   
4. if "%~1"=="" "%~f0" 1|sort /r &pause&exit/b
   
5. 
   
6. :: 启用延迟环境变量扩展，循环中修改变量必须开启
   
7. setlocal enabledelayedexpansion
   
8. :: 清空变量 z，定义变量 b 为 16 个空格（用于数字右对齐）
   
9. set "z=" &for /l %%n in (1,1,16) do set "b= !b!"
   
10. 
    
11. :: 获取系统所有磁盘盘符列表
    
12. for /f "delims=" %%D in ('fsutil fsinfo drives') do set "allD=%%D"
    
13. 
    
14. :: 遍历所有磁盘盘符
    
15. for %%d in (%allD:* =%) do (
    
16.     set "z="
    
17.     rem 嵌套循环：用 fsutil 查询当前磁盘剩余空间，提取关键数值
    
18.     for /f "tokens=2 delims=:(" %%z in ('fsutil volume diskfree %%d') do if not defined z (
    
19.         rem 给变量 z 赋值剩余空间原始数据
    
20.         set "z=%%z"
    
21.         rem 去除数值中的所有空格
    
22.         set "z=!z: =!"
    
23.         rem 去除数值中的千分位逗号
    
24.         set "z=!z:,=!"
    
25. 
    
26.         rem 判断是否为有效数字（过滤光驱、空盘符、无介质驱动器）
    
27.         if "!z:~,1!" geq "1" if "!z:~,1!" leq "9" (
    
28.             rem 前面补 16 个空格，实现右对齐效果
    
29.             set "z=!b!!z!"
    
30.             rem 截取最后 16 个字符，格式化输出
    
31.             set "z=!z:~-16!"
    
32.             rem 输出格式化后的字节数 + 盘符
    
33.             echo,!z!字节 %%d
    
34.         )
    
35.     )
    
36. )
    
37. :: 退出批处理
    
38. exit/b

复制代码

redyear2026

a66 发表于 2026-4-22 14:18
自动遍历电脑所有磁盘（C: D: E:…）
    过滤光驱、空盘符、无介质驱动器
    输出纯数字剩余字节数

阁下再用 ai 解读俺的代码但按照批处语法规范，循环体内的注释行要用 rem 开头，以免运行出现怪错...

guong

不错的方案 学习了